↑  ←  Описание функции

_GUICtrlListBox_Destroy

Удаляет элемент

#include <GuiListBox.au3>
_GUICtrlListBox_Destroy(ByRef $hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает True, устанавливает дескриптор равным 0
Ошибка:Возвращает False

Примечания

Ограничение: применяется только к элементу ListBox, созданному функцией _GUICtrlListBox_Create

См. также

_GUICtrlListBox_Create

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hListBox

    ; Создаёт GUI
    $hGUI = GUICreate("Удаляет ListBox (Созданный в UDF)", 400, 296)
    $hListBox = _GUICtrlListBox_Create($hGUI, "", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет файлы
    _GUICtrlListBox_BeginUpdate($hListBox)
    _GUICtrlListBox_ResetContent($hListBox)
    _GUICtrlListBox_InitStorage($hListBox, 100, 4096)
    _GUICtrlListBox_Dir($hListBox, @WindowsDir & "\win*.exe")
    _GUICtrlListBox_AddFile($hListBox, @WindowsDir & "\Notepad.exe")
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate($hListBox)

    MsgBox(4160, "Информация", "Удаляет ListBox")
    _GUICtrlListBox_Destroy($hListBox)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main