↑  ←  Описание функции

_GUICtrlHeader_ClearFilter

Очищает фильтр

#include <GuiHeader.au3>
_GUICtrlHeader_ClearFilter($hWnd, $iIndex)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlHeader_ClearFilterAll, _GUICtrlHeader_EditFilter

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hHeader

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    _GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

    ; Set up filters
    _GUICtrlHeader_EditFilter ($hHeader, 0)
    Send("Filter 1")
    Sleep(1000)
    Send("{ENTER}")
    _GUICtrlHeader_EditFilter ($hHeader, 1)
    Send("Filter 2")
    Sleep(1000)
    Send("{ENTER}")

    ; Очищает первый фильтр
    _GUICtrlHeader_ClearFilter ($hHeader, 0)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main