↑  ←  Описание функции

_GUICtrlEdit_Create

Создаёт элемент Edit

#include <GuiEdit.au3>
_GUICtrlEdit_Create($hWnd, $sText, $iX, $iY [, $iWidth = 150 [, $iHeight = 150 [, $iStyle = 0x003010C4 [, $iExStyle = 0x00000200]]]])

Параметры

$hWnd Дескриптор родительского окна или окна владельца
$sText Текст, отображаемый в элементе Edit
$iX Горизонтальная координата от левого края
$iY Вертикальная координата от верхнего края
$iWidth [необязательный] Ширина элемента
$iHeight [необязательный] Высота элемента
$iStyle [необязательный] Стили элемента:
    $ES_AUTOHSCROLL - Автоматически сдвигает текст в поле ввода на 10 символов, когда пользователь вводит символ в конце строки у правого края элемента.
    $ES_AUTOVSCROLL - Автоматически прокручивает текст вверх на одну строку, когда пользователь нажимает клавишу ENTER на последней строке.
    $ES_CENTER - Выравнивает текст по центру в многострочном элементе.
    $ES_LEFT - Выравнивает текст по левому краю.
    $ES_LOWERCASE - Преобразует любой вводимый символ верхнего регистра (ЗАГЛАВНЫЕ) в нижний (строчные).
    $ES_MULTILINE - Многострочный
    $ES_NOHIDESEL - Не скрывать выделенное при потере фокуса.
    $ES_NUMBER - Разрешает ввод только цифр.
    $ES_OEMCONVERT - Преобразует вводимый текст в элементе Edit.
    $ES_READONLY - Запрещает пользователю ввод и правку текста.
    $ES_RIGHT - Выравнивает текст по правому краю.
    $ES_UPPERCASE - Преобразует любой вводимый символ нижнего регистра (строчные) в верхний (ЗАГЛАВНЫЕ).
    $ES_WANTRETURN - Вставляет возврат каретки (перенос на новую строку) при нажатии клавиши ENTER при вводе текста в многострочном элементе.
    $ES_PASSWORD - Отображает звёздочки (*) вместо символов при вводе текста.
    По умолчанию: $ES_MULTILINE, $ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL     Принудительный стиль : WS_CHILD, $WS_VISIBLE, $WS_TABSTOP только, если не используется $ES_READONLY
$iExStyle [необязательный] Расширенный стиль элемента. Соответствует стандартным константам $WS_EX_.

Возвращаемое значение

Успех:Возвращает дескриптор элемента Edit
Ошибка:Возвращает 0

Примечания

Эта функция для опытных пользователей и для изучения работы элемента.

См. также

_GUICtrlEdit_Destroy

Пример

#include <GuiEdit.au3>
#include <WinAPI.au3> ; used for Lo/Hi word
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hEdit

_Example1()
_Example2()

Func _Example1()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("Создание окна редактирования", 400, 300)
    $hEdit = _GUICtrlEdit_Create($hGUI, "Это тест" & @CRLF & "Другая строка", 2, 2, 394, 268)
    GUISetState()

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    _GUICtrlEdit_AppendText($hEdit, @CRLF & "Добавленный к концу текст")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Example1

Func _Example2()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("Создание окна редактирования", 400, 300)
    $hEdit = _GUICtrlEdit_Create($hGUI, "", 2, 2, 394, 268)
    GUISetState()

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    _GUICtrlEdit_SetText($hEdit, "Это тест" & @CRLF & "Другая строка")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Example2

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode, $hWndEdit
    If Not IsHWnd($hEdit) Then $hWndEdit = GUICtrlGetHandle($hEdit)
    $hWndFrom = $ilParam
    $iIDFrom = _WinAPI_LoWord($iwParam)
    $iCode = _WinAPI_HiWord($iwParam)
    Switch $hWndFrom
        Case $hEdit, $hWndEdit
            Switch $iCode
                Case $EN_ALIGN_LTR_EC ; Высылается, когда пользователь изменяет направление текста в окне редактирования в состояние слева-направо
                    _DebugPrint("$EN_ALIGN_LTR_EC" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_ALIGN_RTL_EC ; Высылается, когда пользователь изменяет направление текста в окне редактирования в состояние справа-налево
                    _DebugPrint("$EN_ALIGN_RTL_EC" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_CHANGE ; Высылается, когда пользователь выполнил действие, которое может изменить текст в окне редактирования
                    _DebugPrint("$EN_CHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_ERRSPACE ; Высылается, когда окно редактирования не может выделить достаточно памяти для выполнения определённого запроса
                    _DebugPrint("$EN_ERRSPACE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_HSCROLL ; Высылается, когда пользователь кликает горизонтальную прокрутку в окне редактирования
                    _DebugPrint("$EN_HSCROLL" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_KILLFOCUS ; Высылается, когда окно редактирования теряет фокус
                    _DebugPrint("$EN_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_MAXTEXT ; Высылается, когда текущий вставляемый текст превысил указанное число символов для окна редактирования
                    _DebugPrint("$EN_MAXTEXT" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Это сообщение также высылается, когда окно редактирования не имеет стиля $ES_AUTOHSCROLL и количество символов, которое будет вставлено превысит ширину окна редактирования.
                    ; Это сообщение также высылается, когда окно редактирования не имеет стиля $ES_AUTOVSCROLL и общее количество строк в результате вставки текста будет превышать высоту окна редактирования.

                    ; Нет возвращаемых значений
                Case $EN_SETFOCUS ; Высылается, когда окно редактирования получает фокус
                    _DebugPrint("$EN_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_UPDATE ; Высылается, когда окно редактирования собирается перерисовать себя
                    _DebugPrint("$EN_UPDATE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $EN_VSCROLL ; Высылается, когда пользователь кликает вертикальную прокрутку в окне редактирования или прокручивает её колесом мыши
                    _DebugPrint("$EN_VSCROLL" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint