↑  ←  Описание функции

_GUICtrlEdit_BeginUpdate

Предотвращает обновление окна редактирования, пока не будет вызвана функция EndUpdate

#include <GuiEdit.au3>
_GUICtrlEdit_BeginUpdate($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlEdit_EndUpdate

Пример

#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hEdit, $hStatusBar, $hGUI
    Local $sWow64 = ""
    If @autoitx64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Создаёт GUI
    $hGUI = GUICreate("Начало обновления", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI)
    GUISetState()

    _GUICtrlEdit_BeginUpdate($hEdit)
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))
    _GUICtrlEdit_EndUpdate($hEdit)

    _GUICtrlStatusBar_SetText($hStatusBar, @tab & "строк: " & _GUICtrlEdit_GetLineCount($hEdit))
    _GUICtrlStatusBar_SetIcon($hStatusBar, 0, 97, "shell32.dll")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main