↑  ←  Описание функции

_GUICtrlComboBoxEx_SetItemHeight

Устанавливает высоту пунктов в списке или поля ввода в ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItemHeight($hWnd, $iComponent, $iHeight)

Параметры

$hWnd Дескриптор элемента
$iComponent Используйте следующие значения:
    -1 - Устанавливает высоту поля ввода
    0 - Устанавливает высоту пунктов в списке
$iHeight Высота в пикселях, для компонента ComboBox указанного в параметре $iComponent

Возвращаемое значение

Ошибка: Если высота задана неверно, то возвращается значение -1.

См. также

_GUICtrlComboBoxEx_GetItemHeight

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает высоту пункта", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
    Next

    ; MemoWrite("Успешность установки высоты: " & _GUICtrlComboBoxEx_SetItemHeight ($hCombo, -1, 18))
    MemoWrite("Высота пункта: " & _GUICtrlComboBoxEx_GetItemHeight ($hCombo, -1))
    MemoWrite("Успешность установки высоты: " & _GUICtrlComboBoxEx_SetItemHeight ($hCombo, 0, 30))
    MemoWrite("Высота пункта: " & _GUICtrlComboBoxEx_GetItemHeight ($hCombo, 0))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite