Функция _GUICtrlComboBoxEx

_GUICtrlComboBoxEx_GetItem

Возвращает атрибуты пункта

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItem($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор элемента
$iIndex	Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Текст пункта
        [1] - Длина текста пункта
        [2] - Отступ пункта в количестве кратно ширине изображения
        [3] - Индекс пункта изображения, отсчёт от 0
        [4] - Индекс пункта изображения state, отсчёт от 0
        [5] - Индекс пункта изображения overlay, отсчёт от 0
        [6] - Ассоциативное значение пункта

См. также

_GUICtrlComboBoxEx_SetItem, _GUICtrlComboBoxEx_GetItemEx

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $hImage, $aItem, $hCombo

; Создаёт GUI
$hGUI = GUICreate("Получает атрибуты пункта", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
Next

;Устанавливает отступ пункта
_GUICtrlComboBoxEx_SetItemIndent ($hCombo, 1, 1)

$aItem = _GUICtrlComboBoxEx_GetItem ($hCombo, 1)
MemoWrite('Текст пункта .......... : "' & $aItem[0] & '"')
MemoWrite('Длина текста пункта ..........................: ' & $aItem[1])
MemoWrite('Отступ пункта в изображениях ................ : ' & $aItem[2])
MemoWrite('Индекс пункта изображения, отсчёт от 0 ...... : ' & $aItem[3])
MemoWrite('Индекс пункта изображения state, отсчёт от 0..: ' & $aItem[4])
MemoWrite('Индекс пункта изображения overlay, отсчёт от 0: ' & $aItem[5])
MemoWrite('Ассоциативное значение пункта ............... : ' & $aItem[6])

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite