↑  ←  Описание функции

_GUICtrlComboBoxEx_FindStringExact

Поиск строки

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_FindStringExact($hWnd, $sText [, $iIndex = -1])

Параметры

$hWnd Дескриптор элемента
$sText Строка для поиска
$iIndex [необязательный] Индекс пункта, предшествующий пункту с которого начинается поиск. Отсчёт от 0.

Возвращаемое значение

Успех:Возвращает индекс найденного пункта, отсчёт от 0.
Ошибка:Возвращает -1

Примечания

Ищет первое полное совпадение со строкой в параметре $sText (регистр не учитывается)

Если поиск достигает конца списка, то продолжается с начала списка до пункта, указанного в $iIndex включительно.

Если $iIndex = -1, то поиск выполняется по всему списку с самого начала.

См. также

_GUICtrlComboBox_SelectString

Пример

#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hImage, $Delimiter = ";", $hCombo

    Opt("GUIDataSeparatorChar", $Delimiter)

    ; Создаёт GUI
    $hGUI = GUICreate("Поиск полного совпадения строки", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "Это строка;мОй тЕкСт", 2, 2, 394, 100, $CBS_SIMPLE)
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)), $x, $x)
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    ; Найти точную строку
    MsgBox(4160, "Информация", "Найдено в : " & _GUICtrlComboBoxEx_FindStringExact ($hCombo, "мой текст"))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main