_GDIPlus_MatrixRotate
Обновляет матрицу с продуктом в себе и вращает матрицу
#include <GDIPlus.au3>
_GDIPlus_MatrixRotate($hMatrix, $fAngle [, $bAppend = False])
Параметры
| $hMatrix | Дескриптор объекта Matrix |
| $fAngle |
Угол поворота в градусах. Положительные значения указывают вращение по часовой стрелке. |
| $bAppend |
[необязательный] Указывает порядок умножения: True - Указывает, что вращение матрицы влево False - Указывает, что вращение матрицы вправо |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
Искать GdipRotateMatrix в библиотеке MSDNПример
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic, $width, $height
; Инициализация библиотеки GDI+
_GDIPlus_Startup()
; Захватывает весь экран
$hBitmap1 = _ScreenCapture_Capture("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
; Захватывает область экрана
$hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)
$width = _GDIPlus_ImageGetWidth($hImage2)
$height = _GDIPlus_ImageGetHeight($hImage2)
; Рисует одно изображение в другом
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)
;DrawInsert($hGraphic, $hImage2, $iX, $iY, $nAngle, $iWidth, $iHeight, $iARGB = 0xFF000000, $nWidth = 1)
DrawInsert($hGraphic, $hImage2, 350, 100, 0, $width + 2, $height + 2, 0xFFFF8000, 2)
DrawInsert($hGraphic, $hImage2, 340, 50, 15, 200, 150, 0xFFFF8000, 4)
DrawInsert($hGraphic, $hImage2, 310, 30, 35, $width + 4, $height + 4, 0xFFFF00FF, 4)
DrawInsert($hGraphic, $hImage2, 320, 790, -35, $width, $height)
; Сохраняет изображение в файл
_GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Очищает ресурсы
_GDIPlus_ImageDispose($hImage1)
_GDIPlus_ImageDispose($hImage2)
_WinAPI_DeleteObject($hBitmap1)
_WinAPI_DeleteObject($hBitmap2)
; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc ;==>_Main
; #FUNCTION# ==================================================================================================
; Name...........: DrawInsert
; Description ...: Рисует одно изображение в другом
; Syntax.........: DrawInsert($hGraphic, $hImage2, $iX, $iY, $nAngle, $iWidth, $iHeight, $iARGB = 0xFF000000, $nWidth = 1)
; вставляет изображение $hImage2 в $hGraphic
; Parameters ....:
; $hGraphics - Дескриптор графического объекта
; $hImage - Дескриптор вставляемого объекта изображения
; $iX - X-координата левого верхнего угла вставляемого изображения
; $iY - Y-координата левого верхнего угла вставляемого изображения
; $nAngle - угол
; $iWidth - ширина прямоугольника, который образует рамку
; $iHeight - высота прямоугольника, который образует рамку
; $iARGB - Альфа канал, Красный, Зелёный и Синий компоненты цвета пера/карандаша - (цвет рамки)
; $nWidth - толщина пера/карандаша, размерность единицы которого указана в параметре $iUnit - (толщина рамки)
; Return values .: Успех - True
; Ошибка - False
;==================================================================================================
Func DrawInsert($hGraphic, $hImage2, $iX, $iY, $nAngle, $iWidth, $iHeight, $iARGB = 0xFF000000, $nWidth = 1)
Local $hMatrix, $hPen2
; Вращение матрицы
$hMatrix = _GDIPlus_MatrixCreate()
_GDIPlus_MatrixRotate($hMatrix, $nAngle, "False")
_GDIPlus_GraphicsSetTransform($hGraphic, $hMatrix)
_GDIPlus_GraphicsDrawImage($hGraphic, $hImage2, $iX, $iY)
; Создаёт перо/карандаш указанного цвета и толщины
$hPen2 = _GDIPlus_PenCreate($iARGB, $nWidth)
; Рисует рамку вокруг вставленного изображения
_GDIPlus_GraphicsDrawRect($hGraphic, $iX, $iY, $iWidth, $iHeight, $hPen2)
; Очищает ресурсы
_GDIPlus_MatrixDispose($hMatrix)
_GDIPlus_PenDispose($hPen2)
Return 1
EndFunc ;==>DrawInsert