↑  ←  Описание функции

_GDIPlus_GraphicsDrawRect

Рисует прямоугольник

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawRect($hGraphics, $iX, $iY, $iWidth, $iHeight [, $hPen = 0])

Параметры

$hGraphics Дескриптор графического объекта
$iX X-координата верхнего левого угла прямоугольника
$iY Y-координата верхнего левого угла прямоугольника
$iWidth Ширина прямоугольника
$iHeight Высота прямоугольника
$hPen [необязательный] Дескриптор объекта карандаша, который используется для рисования прямоугольника. Если 0, то чёрная линия шириной 1 пиксель.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

Искать GdipDrawRectangleI в библиотеке MSDN

Пример

#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphics

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup ()

    ; Захватывает весь экран
    $hBitmap1 = _ScreenCapture_Capture ("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap1)

    ; Захватывает область экрана
    $hBitmap2 = _ScreenCapture_Capture ("", 0, 0, 400, 300)
    $hImage2 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap2)

    ; Рисует одно изображение в другом
    $hGraphics = _GDIPlus_ImageGetGraphicsContext ($hImage1)
    _GDIPlus_GraphicsDrawImage ($hGraphics, $hImage2, 100, 100)

    ; Рисует рамку вокруг вставленного изображения
    _GDIPlus_GraphicsDrawRect ($hGraphics, 100, 100, 400, 300)

    ; Сохраняет изображение в файл
    _GDIPlus_ImageSaveToFile ($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Очищает ресурсы
    _GDIPlus_ImageDispose ($hImage1)
    _GDIPlus_ImageDispose ($hImage2)
    _WinAPI_DeleteObject ($hBitmap1)
    _WinAPI_DeleteObject ($hBitmap2)

    ; Закрывает библиотеку GDI+
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main