↑  ←  Описание функции

_GDIPlus_ArrowCapGetFillState

Determines whether the arrow cap is filled

#include <GDIPlus.au3>
_GDIPlus_ArrowCapGetFillState($hArrowCap)

Параметры

$hArrowCap Handle to a ArrowCap object

Возвращаемое значение

True :Arrow cap is filled
False :Arrow cap is not filled or if error then @error is set

См. также

_GDIPlus_ArrowCapSetFillState

См. также

Искать GdipGetAdjustableArrowCapFillState в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Создаёт ресурсы
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate (4, 6)

    ; Show fill state
    MsgBox(4096, "Информация", "Fill state: " & _GDIPlus_ArrowCapGetFillState($hEndCap))

    ; Рисует стрелку 1
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)

    ; Рисует стрелку 2
    _GDIPlus_ArrowCapSetFillState($hEndCap, False)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 160, 390, 160, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_ArrowCapDispose ($hEndCap)
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_Shutdown ()
EndFunc   ;==>_Main