↑  ←  Описание функции

_GDIPlus_PenSetCustomEndCap

Sets the custom end cap for the pen

#include <GDIPlus.au3>
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)

Параметры

$hPen Дескриптор объекта Карандаш
$hEndCap Handle to a CustomLineCap object that specifies the pen custom end cap

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GDIPlus_PenGetCustomEndCap

См. также

Искать GdipSetPenCustomEndCap в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Создаёт ресурсы
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
    _GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)

    ; Show pen end cap
    MsgBox(4096, "Информация", "Pen end cap: " & _GDIPlus_PenGetCustomEndCap ($hPen))

    ; Рисует стрелки
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 6)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 8)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 200, 390, 200, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main