↑  ←  Описание функции

TraySetState

Устанавливает состояние иконки в трее.

TraySetState ( [ flag = 1 ] )

Параметры

flag [необязательный] Может быть комбинацией следующих значений:
1 - (по умолчанию) Отображает иконку в трее
2 - Удаляет/Скрывает иконку в трея
4 - Мигает иконка в трее
8 - Мигание иконки остановлено
16 - Сброс иконки в состояние по умолчанию (не мигает, текст всплывающей подсказки по умолчанию)

Примечания

Эта функция переопределяет опцию TrayIconHide и установку #NoTrayIcon.
Стандартная иконка и иконка паузы в трее не сбрасываются этой функцией!

См. также

TrayItemSetState, TraySetIcon, TraySetPauseIcon

Пример

#NoTrayIcon

Opt("TrayMenuMode", 1 + 2) ; Не отображать в трее пункты меню по умолчанию (Script Paused/Exit) и не отмечать галочками при выборе.

Local $iFlash = TrayCreateItem("Мигать иконкой")
TrayCreateItem("") ; Создаёт разделитель

Local $iExit = TrayCreateItem("Выход")

TraySetState(1) ; Показывает меню трея

While 1
    Switch TrayGetMsg()

        Case $iFlash
            ; Мигает иконкой в трее.
            TraySetState(4)
            Sleep(5000) ; Ожидание 5 секунд.
            ; Останавливает мигание иконкой в трее.
            TraySetState(8)

        Case $iExit ; Выход
            ExitLoop
    EndSwitch
WEnd