Вставка строки в файл

[OXIGEN]

Здравствуйте.

Есть скриптик вставляющий строку с определённым текстом в оределённое место в текстовый фаил.

$aFile = FileReadToArray("1 AUTO.au3")

$fNew = FileOpen("1 AUTO.au3",2)
$StringCount = UBound($aFile)-1
$StringToInsert = $StringCount-3  ; количество строк от конца до вставки (3)

for $i=0 to $StringCount
    FileWriteLine($fNew, $aFile[$i])
    if $i = $StringToInsert then FileWriteLine($fNew, "ХХХХХ Текст во вставляемой строке ХХХХХ")
Next

FileClose($fNew)

Но он считает строки от конца файла, ни как не соображу, как сделать, что-бы считал от начала файла. В описании функции UBound
вроде не нашол или не понял как... Подскажите? И ещё...

Есть каталог(папка) "START", в НЕЙ около сотни других папок с разнами именами. Но в каждой из папок есть файл с одинаковым именем.
Допустим - "1 AUTO.au3". Как прописать путь, что бы скопировать строку из вышеприведённого скрипта в каждый фаил "1 AUTO.au3" во
все папки с разными именами, находящиеся в корневой папке "START" ?
Спасибо.

 

[InnI]

как сделать, что-бы считал от начала файла

Просто укажите номер строки

;$StringToInsert = $StringCount - 3  ; количество строк от конца до вставки (3)
$StringToInsert = 3

скопировать строку в каждый фаил "1 AUTO.au3" во все папки с разными именами

За испорченные файлы ответственности не несу.
Обязательно сделайте резервную копию и проверьте путь к папке.

Спойлер

#include <File.au3>

$RootPath = @ScriptDir & "\start" ; путь к корневой папке
$FileName = "1 AUTO.au3" ; имя файла

$NumStr = 4 ; номер строки
$Str = "Текст во вставляемой строке" ; строка для вставки

$aFiles = _FileListToArrayRec($RootPath, $FileName, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_NOSORT, $FLTAR_FULLPATH)
If @error Then Exit MsgBox(0, "_FileListToArrayRec", "@error=" & @error & " (см. справку)")

For $f = 1 To $aFiles[0]
  _FileWriteToLine($aFiles[$f], $NumStr, $Str)
  If @error Then ConsoleWrite($aFiles[$f] & " | @error=" & @error & " (см. справку)" & @CRLF)
Next

 

[OXIGEN]

Большое СПАСИБО! (Ничего не испортилось)... ВСЁ РАБОТАЕТ как НАДО!...