Сделать возможным закрытия окошка после выполнения действия

[SharkX58]

Подскажите, хочу сделать напоминалку. Как сделать, чтобы окно не могли закрыть крестиком в верхнем правом углу, а могли закрыть только когда проставят все галочки и окошко было по верх всех окон.

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Local $nCh1, $nCh2, $nCh3, $nCh4, $nCh5, $nCh6, $nCh7, $nCh8, $msg
GUICreate("Проверка Администратора салона") ; Создаёт окно в центре экрана

$nCh1 = GUICtrlCreateCheckbox("1. Доброе утро- с позитивным настроением начало рабочего дня.", 10, 10, 400, 17)

$nCh2 = GUICtrlCreateCheckbox("2. Уборка салона до 10.00", 10, 50, 400, 17)

$nCh3 = GUICtrlCreateCheckbox("3. Постановка задач на день- настрой команды на результат", 10, 90, 400, 17)

$nCh4 = GUICtrlCreateCheckbox("4. Фото персонала в чат", 10, 130, 400, 17)

$nCh5 = GUICtrlCreateCheckbox("5. Обсуждение личных продаж, % выполнения плана салоном", 10, 170, 400, 17)

$nCh6 = GUICtrlCreateCheckbox("6. Провести чек лист до 11.00", 10, 210, 400, 17)

$nCh7 = GUICtrlCreateCheckbox("7. Работа с товаром- брак, ремонт, переоценка, мерч", 10, 250, 400, 17)

$nCh8 = GUICtrlCreateCheckbox("8. Ежедневное обучение и тренировки персонала.", 10, 290, 400, 17)



GUISetState() ; показывает созданное окно

GUICtrlCreateButton("Выполнено", 300, 360)

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

Используйте для AutoIt кода тег [autoit]

madmasles.

 

[inververs]

#NoTrayIcon

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
GUICreate("Проверка Администратора салона", -1, -1, -1, -1, BitOR($WS_MINIMIZEBOX,$WS_POPUP,$WS_GROUP), BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE)) ; Создаёт окно в центре экрана
Local $nCh1 = GUICtrlCreateCheckbox("1. Доброе утро- с позитивным настроением начало рабочего дня.", 10, 10, 400, 17)
Local $nCh2 = GUICtrlCreateCheckbox("2. Уборка салона до 10.00", 10, 50, 400, 17)
Local $nCh3 = GUICtrlCreateCheckbox("3. Постановка задач на день- настрой команды на результат", 10, 90, 400, 17)
Local $nCh4 = GUICtrlCreateCheckbox("4. Фото персонала в чат", 10, 130, 400, 17)
Local $nCh5 = GUICtrlCreateCheckbox("5. Обсуждение личных продаж, % выполнения плана салоном", 10, 170, 400, 17)
Local $nCh6 = GUICtrlCreateCheckbox("6. Провести чек лист до 11.00", 10, 210, 400, 17)
Local $nCh7 = GUICtrlCreateCheckbox("7. Работа с товаром- брак, ремонт, переоценка, мерч", 10, 250, 400, 17)
Local $nCh8 = GUICtrlCreateCheckbox("8. Ежедневное обучение и тренировки персонала.", 10, 290, 400, 17)
Local $close = GUICtrlCreateButton("Выполнено", 300, 360)
GUICtrlSetState($close, $GUI_DISABLE)
GUISetState() ; показывает созданное окно
Local $count = 0
While 1
    $msg = GUIGetMsg()
	Switch $msg
		Case $nCh1, $nCh2, $nCh3, $nCh4, $nCh5, $nCh6, $nCh7, $nCh8
			If GUICtrlRead($msg) = 1 Then
				$count+=1
			Else
				$count-=1
			EndIf

			If $count = 8 Then
				GUICtrlSetState($close, $GUI_ENABLE)
			Else
				GUICtrlSetState($close, $GUI_DISABLE)
			EndIf
		Case $close
			If $count = 8 Then ExitLoop
	EndSwitch
WEnd