[RegExp] Извлечение данных из строки

[sforce5]

Здрасьте!

Существует выражение: {lnglst:Russian|English|Ukrainian}

нужно получить массив этих самых ln-глистов lnglist'ов

Например массив $aLanguage:

$aLanguage[0] - кол-во этих самых
$aLanguage[1] - первый язык (в данном случае Russian)
$aLanguage[2] - English
$aLanguage[3] - Ukrainian
$aLanguage[9000]

Помогите!)

 

[madmasles]

sforce5
У меня так поучилось:

#include <Array.au3>

$sString = '{lnglst:Russian|English|Ukrainian}'
$aTemp = StringRegExp($sString, ':(.*?)}', 3)
If IsArray($aTemp) Then
	$aLanguage = StringSplit($aTemp[0], '|')
	_ArrayDisplay($aLanguage, '$aLanguage')
EndIf

 

[SyDr]

А зачем здесь регулярные выражения?

$sList = '{lnglst:Russian|English|Ukrainian}'
$sList = StringTrimLeft($sList, 8)
$sList = StringTrimRight($sList, 1)
$aList = StringSplit($sList, "|")

 

[madmasles]

Без регулярных выражений у меня еще так получилось:

#include <Array.au3>

$sString = '{lnglst:Russian|English|Ukrainian}'
$aLanguage = StringSplit(StringMid($sString, StringInStr($sString, ':') + 1, StringInStr($sString, '}') - StringInStr($sString, ':') - 1), '|')
_ArrayDisplay($aLanguage, '$aLanguage')

 

[Yashied]

Я не проверял, но думаю StringSplit(), одна из самых быстрых функций обработки строк в AutoIt. Так что предпочтительнее использовать ее.

 

[CreatoR]

А вот так это делается одним выражением:

#include <Array.au3>

$sString = '{lnglst:Russian|English|Ukrainian}'
$aLanguage = StringRegExp($sString, '(?:{lnglst:)?(.*?)(?:\||})', 3)
_ArrayDisplay($aLanguage, '$aLanguage')

правда это занимает нулевой элемент.

А со StringSplit я бы сделал так:

$sString = '{lnglst:Russian|English|Ukrainian}'
$aLanguage = StringSplit(StringMid($sString, 9, StringLen($sString)-9), '|')

или можно ещё так поизвращаться:

$sString = '{lnglst:Russian|English|Ukrainian}'
$aLanguage = StringSplit($sString, '|:}', 2)
$aLanguage[0] = UBound($aLanguage)-2
ReDim $aLanguage[$aLanguage[0]+1]

;D

 

[DOZOMIGAMIUS]

А в Экселе при помощи CЧЁТЕСЛИ() не пробывал?

Столбец А$ - эти данные

Ячейка Б1=Счётесли(A:A;"ИСКОМОЕ ЗНАЧЕНИЕ") ячейка будет равнятся количеству искомых критериев

 

[sforce5]

А в Экселе при помощи CЧЁТЕСЛИ() не пробывал?

Ох, как жэ я забылЪ про быдлоэксэль. Возможно я не подумал про эксэль потому что здесь он протсо неуместен!

Было бы написано "[ЭКЗЭЛЪ] Излечение данных из ичейки строки"