Преобразование ответа от сервера в массив!

[RogeR31415]

Получаем данные от сервера:

$oRequest.Send('request=get-data')
	$sData = $oRequest.ResponseText

...данные типа string такого вида:

Array
(
    [0] => Array
        (
            [0] => Array
                (
                    [Last name] => Pervyi
                    [First name] => Petr
                )

            [1] => Array
                (
                    [Last name] => Pupkin
                    [First name] => Vasya
                )

            [2] => Array
                (
                    [Last name] => TestLast
                    [First name] => TestName
                )

        )

)

Как преобразовать строку в массив вида:

Array =>     
              array[0] => 
                                 [Last name] => Pervyi
                                 [First name] => Petr
              array[1] => 
                                 [Last name] => Pupkin
                                 [First name] => Vasya

Регулярными выражениями?

 

[madmasles]

RogeR31415,
Попробуйте так.

#include <Array.au3>

;...
;$sData = $oRequest.ResponseText
$sData = FileRead(@ScriptDir & '\1.txt')
$aTemp = StringRegExp($sData, '(?s)(\[Last name\].*?\[First name\][^\r\n]+)', 3)
Dim $a_Ret[UBound($aTemp) + 1] = [UBound($aTemp)]
For $i = 1 To $a_Ret[0]
	$a_Ret[$i] = StringRegExpReplace($aTemp[$i - 1], '\h{2,}', '')
Next
_ArrayDisplay($a_Ret, '1')
;or
Dim $a_Ret_1[UBound($aTemp) + 1][2] = [['Last name', 'First name']]
For $i = 0 To UBound($aTemp) - 1
	$a_Temp = StringSplit(StringStripCR($aTemp[$i]), @LF)
	For $j = 1 To $a_Temp[0]
		$a_Ret_1[$i + 1][$j - 1] = StringReplace(StringStripWS($a_Temp[$j], 7), '[' & $a_Ret_1[0][$j - 1] & '] => ', '')
	Next
Next
_ArrayDisplay($a_Ret_1, '2')

 

[RogeR31415]

Спасибо! Но Не совсем то что хочется... Наверное будет легче получить массив который я хочу с json...

[{"Last name":"Pervyi","First name":"Petr"},{"Last name":"Pupkin","First name":"Vasya"},{"Last name":"TestLast","First name":"TestName"}]

Теперь регулярку подобрать надо...

 

[inververs]

Для последней строки которую вы дали:

#include <Array.au3>
$sString = '[{"Last name":"Pervyi","First name":"Petr"},{"Last name":"Pupkin","First name":"Vasya"},{"Last name":"TestLast","First name":"TestName"}]'
$aData = StringRegExp($sString,'(?<=\Qname":"\E)([^"]+)',3)
_ArrayDisplay($aData)

 

[RogeR31415]

Спасибо! Класс! Все что просто - гениально. И последнее как поправить шаблон, чтобы возвращался массив даже с элементом который пуст... Например

[{"Last name":"Pervyi","Phone":"","First name":"Petr"},{"Last name":"Pupkin","Phone":"","First name":"Vasya"},{"Last name":"TestLast","Phone":"65465456","First name":"TestName"}]

А то как сейчас, где пустота пропускает этот элемент, а мне нужно чтобы колво элементов было фиксированым..

 

[inververs]

Проблемно найти то чего нет. Вместо этого, могу предложить заменять "ничто" чем нибудь, что найдется первым. Вот например:

#include <Array.au3>
$sString = '[{"Last name":"Pervyi","Phone":"","First name":"Petr"},{"Last name":"Pupkin","Phone":"","First name":"Vasya"},{"Last name":"TestLast","Phone":"65465456","First name":"TestName"}]'
$aData = StringRegExp($sString,'(?<=\Q":"\E)(?:([^"]+)|.)',3)
_ArrayDisplay($aData)

Добавлено:

Сообщение автоматически объединено: 23 Авг 2012

Хотя можно и так:

#include <Array.au3>
$sString = '[{"Last name":"Pervyi","Phone":"","First name":"Petr"},{"Last name":"Pupkin","Phone":"","First name":"Vasya"},{"Last name":"TestLast","Phone":"65465456","First name":"TestName"}]'
$aData = StringRegExp($sString,'(?<=\Q":"\E)(?:([^"]+)|)',3)
_ArrayDisplay($aData)

 

[RogeR31415]

жесть! Спс

 

[MockeR]

можно и так:

#include <Array.au3>
$sString = '[{"Last name":"Pervyi","Phone":"","First name":"Petr"},{"Last name":"Pupkin","Phone":"","First name":"Vasya"},{"Last name":"TestLast","Phone":"65465456","First name":"TestName"}]'
$aData = StringRegExp($sString, ':"([^"]*)', 3)
_ArrayDisplay($aData)

или так:

#include <Array.au3>
$sString = '[{"Last name":"Pervyi","Phone":"","First name":"Petr"},{"Last name":"Pupkin","Phone":"","First name":"Vasya"},{"Last name":"TestLast","Phone":"65465456","First name":"TestName"}]'
$aData = StringRegExp($sString, ':"(.*?)"', 3)
_ArrayDisplay($aData)

 

[RogeR31415]

Круть! Спасибо! А вы как регулярные выражения подбираете? Я в смысле пользуется кто онлайн подбором регулярок, и есть ли вообще такие?

 

[MockeR]

RogeR31415, через это чаще всего: http://gskinner.com/RegExr/

 

[kaster]

OffTopic:
в таких случаях остро ощущается нехватка вменяемого парсера для различных форматов, будь то json или xml