[Мышь, клавиатура] Как записать позицию мыши в файл и потом его использовать?

[zelich]

Мне надо навести мышь на "Элемент". И потом использовать эти координаты... Как записать в файл или хотяб их узнать?

 

[sngr]

Au3Record пишет в файл координаты мыши, в au3info можешь их посмотреть сам.

 

[madmasles]

zelich,

HotKeySet('{Esc}', '_Exit')
HotKeySet('^1', '_Save')
While 1
	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)
	ToolTip($iX & 'x' & $iY, 0, 0)
	Sleep(100)
WEnd

Func _Save()
	FileWrite(@ScriptDir & '\MousePos.txt', $iX & 'x' & $iY & @CRLF)
EndFunc   ;==>_Save

Func _Exit()
	Exit
EndFunc   ;==>_Exit

 

[zelich]

madmasles
А как их потом использовать?

 

[madmasles]

zelich [?]

А как их потом использовать?

Прочитать из файла.
Записать:

Global $iX, $iY, $iCount

HotKeySet('{Esc}', '_Exit')
HotKeySet('^1', '_Save')

While 1
	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)
	ToolTip($iX & 'x' & $iY, 0, 0)
	Sleep(100)
WEnd

Func _Save()
	$iCount += 1
	IniWrite(@ScriptDir & '\MousePos.ini', 'MousePos', $iCount, $iX & '|' & $iY)
EndFunc   ;==>_Save

Func _Exit()
	Exit
EndFunc   ;==>_Exit

Использовать:

Global $sString, $iCount, $aPos

While 1
	$iCount += 1
	$sString = IniRead(@ScriptDir & '\MousePos.ini', 'MousePos', $iCount, 'Error')
	If $sString <> 'Error' Then
		$aPos = StringSplit($sString, '|')
		If $aPos[0] = 2 Then
			MouseMove(Int($aPos[1]), Int($aPos[2]))
		EndIf
	Else
		ExitLoop
	EndIf
	Sleep(500)
WEnd

 

[AZJIO]

zelich

; получили
$aPos = MouseGetPos()
$text=$aPos[0] & "," & $aPos[1]

; записали
$file = FileOpen(@ScriptDir&'\file.txt',2)
FileWrite($file, $text)
FileClose($file)

; прочитали
$text = FileRead(@ScriptDir&'\file.txt')
$aPos = StringSplit($text, ',', 2)

; выдали
MsgBox(0, "Координаты курсора мыши:", 'X= '&$aPos[0] & ", Y= " & $aPos[1])