Меняем название кнопки

[CreatiK]

Добрый день. Начну с этого если я неправильно назвал тему то подскажите пожалуйста))

Теперь по теме: есть программа вот скрин

как сделать чтобы я нажимал на кнопку 1 минута и надпись изменилась на Стоп и имела уже другую Func(чтобы остановить) ?

и второй вопрос как сделать чтобы вот я выбрал повтор через 5 минут а остальные кнопки стали не активны до нажатия кнопки стоп

 

[Guezt]

смотря какой режим ты используешь event или loop вот пример на Event

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt("GUIOnEventMode", 1)
Global $i=0
GUICreate('Кнопка',120,100,-1,-1)
$b = GUICtrlCreateButton('1 минута',10,15,80,20)
GUICtrlSetOnEvent(-1,'_fun1')
GUISetOnEvent($GUI_EVENT_CLOSE, "_Close")
$l = GUICtrlCreateLabel($i,10,50,100)
GUISetState(@SW_SHOW)

Func _Close()
	Exit
EndFunc

Func _fun1()
	AdlibRegister('_fun',10)
	GUICtrlSetOnEvent($b,'_fun2')
	GUICtrlSetData($b,'стоп')
EndFunc

Func _fun()
	$i=$i+1
	GUICtrlSetData($l,$i)
EndFunc

Func _fun2()
	AdlibUnRegister('_fun')
	GUICtrlSetOnEvent($b,'_fun1')
	GUICtrlSetData($b,'1 минута')
	$i=0
	GUICtrlSetData($l,$i)
EndFunc

While 1
	Sleep(100)
WEnd

Добавлено:

Сообщение автоматически объединено: 5 Фев 2011

вот в режиме loop

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Global $i=0
Global $chk = 0
GUICreate('Кнопка',120,100,-1,-1)
$b = GUICtrlCreateButton('1 минута',10,15,80,20)
$l = GUICtrlCreateLabel($i,10,50,100)
GUISetState(@SW_SHOW)


Func _fun()
	$i=$i+1
	GUICtrlSetData($l,$i)
EndFunc


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
			Case $GUI_EVENT_CLOSE
				Exit
			Case $b
				if $chk	=0 Then
					AdlibRegister('_fun',10)
	                GUICtrlSetData($b,'стоп')
					$chk = 1
				Else
					AdlibUnRegister('_fun')
				   GUICtrlSetData($b,'1 минута')
				   $i=0
				   GUICtrlSetData($l,'0')
				   $chk = 0
				EndIf
	EndSwitch
WEnd

Добавлено:

Сообщение автоматически объединено: 5 Фев 2011

что бы кнопки стали неактивны есть параметр

GUICtrlSetState()

 

[CreatiK]

Guezt Gutsy

GUICtrlSetData($l,'0')

Для чего это? Просто не пойму)

Все разобрался))) Спасибо, помог)