Как сделать аттач в тело письма в функции _INetSmtpMailCom

[Yuri]

Здравствуйте.
Написал скрипт на основе
http://www.autoitscript.com/forum/index.php?showtopic=23860
Все работает. Но интересует вставка аттача в письмо таким образом,
чтобы он был в теле письма, а не во вложении (т.е. текст html страницы и изображения этой html в теле письма)
Это вообще осуществимо?
Кусок кода вначале такой:

$SmtpServer = "127.0.0.1"
$FromName = "User"
$FromAddress = "[email protected]" 
$ToAddress = "[email protected]"
$Subject = "Тема сообщения"
$Body = "Текст сообщения"
$AttachFiles = "D:\Zima.htm" 
$CcAddress = ""
$BccAddress = ""
$Importance = "Normal"
$Username = ""
$Password = ""
$IPPort = 25
$ssl = 0

###############################
Почему-то продублировался мой вопрос.
Надо бы лишнюю копию удалить как-то.
Не знаю как это сделать.
**********************
Тему закрываю (решено)
Разобрался.
Мое решение:
Проанализировав код:
If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
$objEmail.HTMLBody = $as_Body
Else
$objEmail.Textbody = $as_Body & @CRLF
EndIf
Понял, что CDO.Message надо курить (но не осилил)
Потом исходник вышеприведенный стал изучать конкретно.
Понял, что HTML текст нужен в $Body
Создал файл 111.htm (такой какой мне нужен)
Теперь его и надо зааттачить в ТЕЛО.
Открыл его для чтения, прочел, записал в переменную, закрыл.
Правда, без рисунков, изображений и т.п.

Воткод:

#Include<file.au3>
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
Call("Telo")

Func Telo()
$file = FileOpen("D:\M_B_1.html", 0)
If $file = -1 Then
    MsgBox(16, "Ошибка", "Попытка открытия файла неудалась")
    Exit
EndIf
$Telo = FileRead($file)
MsgBox(0, "Char read:", $Telo)
FileClose($file)
Global $Body = $Telo
EndFunc

$SmtpServer = "127.0.0.1"
$FromName = "Aleksandr"
$FromAddress = "[email protected]"
$ToAddress = "[email protected]"
$Subject = "Моя тема"
$AttachFiles = ""
$CcAddress = ""
$BccAddress = ""
$Importance = "Normal"
$Username = ""
$Password = ""
$IPPort = 25
$ssl = 0 

Call("SendMail")

Func SendMail()
$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
If @error Then
    MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
EndIf
EndFunc
;
; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
            ConsoleWrite('@@ Debug(62) : $S_Files2Attach = ' & $S_Files2Attach & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
EndFunc   ;==>_INetSmtpMailCom
;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc

Все.