Как объединить несколько inputbox в одну?

[rufik]

Хочу сделать, чтобы вышло окно, где заполняешь одновременно несколько полей(чтобы не было несколько последовательных окон)...
например:
Ваш ник:
Ваш пароль:
Интервал обновления:
и т.д.
И еще, как можно сделать, чтобы вышли значения и выбирать их, или одну, который тебя устраивает
например:
Интервал обновления:
10 сек
20 сек
30 сек
И выбираешь одну из них(птичкой или другим способом)
Заранее спасибо за помощь!

 

[CreatoR]

rufik
А при чём здесь «Автоматизация IE и Web-интерфейса»?

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>

$hGUI = GUICreate("Test Script", 300, 200)

GUICtrlCreateLabel("Ваш ник:", 20, 23)
$iLogin_Input = GUICtrlCreateInput("", 100, 20, 180, 20)

GUICtrlCreateLabel("Ваш пароль:", 20, 53)
$iPassword_Input = GUICtrlCreateInput("", 100, 50, 180, 20, BitOR($GUI_SS_DEFAULT_INPUT, $ES_PASSWORD))

GUICtrlCreateLabel("Интервал обновления:", 20, 83)
$iUpdateIntrvl_Input = GUICtrlCreateCombo("", 150, 80, 130, 50, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($iUpdateIntrvl_Input, "10 сек|20 сек|30 сек", "10 сек")

$iOK_Button = GUICtrlCreateButton("OK", 20, 170, 80, 20)

GUISetState(@SW_SHOW, $hGUI)

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $iOK_Button
			$sLogin = GUICtrlRead($iLogin_Input)
			$sPassword = GUICtrlRead($iPassword_Input)
			$iInterval = GUICtrlRead($iUpdateIntrvl_Input)
			
			$sInfo = StringFormat("Логин:\t\t%s\nПароль:\t\t%s\nИнтервал:\t%i", $sLogin, $sPassword, $iInterval)
			
			MsgBox(64, 'Инфо', $sInfo, 0, $hGUI)
	EndSwitch
WEnd

 

[rufik]

спасибо!