Изменение размера шрифта отдельных слов в выводимом окне или хинте

[blacksergo]

Подскажите, как изменить размер шрифта отдельных слов в выводимом окне или подсказке к элементу (хинте)

 

[CreatoR]

В окне - GUISetFont.
В подсказке - возможно нужно покапаться в _GUIToolTip_*.

 

[saraconor]

а в Tooltip можно поменять цвет \ размер \ шрифт ?

 

[madmasles]

saraconor [?]

а в Tooltip можно поменять цвет \ размер \ шрифт ?

#include <WinAPI.au3>
#include <FontConstants.au3>

$sInfo = StringFormat('%-20s:%3s\n%-20s:%3s\n%-20s:%3s\n%-20s:%3s\n%-20s:%3s\n%-20s:%3s\n', 'Задание', 1, 'Номер ошибки', 2, 'Время начала', 3, 'Время окончания', 4, _
		'Время выполнения', 5, 'Описание ошибки', 6)
ToolTip($sInfo, 0, 0, 'Test', 1, 1)
$hToolTip = _GetToolTip($sInfo)
If $hToolTip Then
	$hFont = _WinAPI_CreateFont(14, 0, 0, 0, 400, False, False, False, $DEFAULT_CHARSET, $OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Lucida Console')
	_WinAPI_SetFont($hToolTip, $hFont)
EndIf
HotKeySet('{ESC}', '_EXIT')

While 1
	Sleep(250)
WEnd

Func _EXIT()
	_WinAPI_DeleteObject($hFont)
	Exit
EndFunc   ;==>_EXIT

Func _GetToolTip($s_Text)
	Local $a_ToolTip, $h_ToolTip
	$a_ToolTip = WinList('[Class:tooltips_class32]')
	If Not $a_ToolTip[0][0] Then Return $h_ToolTip
	For $i = 1 To $a_ToolTip[0][0]
		If Not BitAND(WinGetState($a_ToolTip[$i][1]), 2) Then ContinueLoop
		If StringInStr(WinGetTitle($a_ToolTip[$i][1]), $s_Text) Then
			$h_ToolTip = $a_ToolTip[$i][1]
			ExitLoop
		EndIf
	Next
	Return $h_ToolTip
EndFunc   ;==>_GetToolTip

 

[AZJIO]

http://autoit-script.ru/index.php/topic,12926.msg83032.html#msg83032