GUICtrlCreateButton - можно ли убрать рамку?

[QQruza]

Можно ли убрать синюю рамку вокруг GUICtrlCreateButton?

$Form = GUICreate("Form", 140, 100, 441, 172)
GUISetBkColor(0x111111)

$Button = GUICtrlCreateButton("Кнопка", 10, 10, 120, 60)
GUICtrlSetFont(-1, 18, 800, 0, "Arial")
GUICtrlSetBkColor(-1, 0x444444)
GUICtrlSetColor(-1, 0xffffff)

GUISetState(@SW_SHOW)

 

[joiner]

Local $Form1 = GUICreate("Form1", 140, 100, 441, 172)
GUISetBkColor(0x111111)
Local $Label1 = GUICtrlCreateLabel("Кнопка", 10, 10, 120, 60, $SS_CENTERIMAGE + $SS_CENTER)
GUICtrlSetFont(-1, 18, 800, 0, "Arial")
GUICtrlSetBkColor(-1, 0x444444)
GUICtrlSetColor(-1, 0xffffff)
GUISetState()
Local $aInfC

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 16, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, $WS_EX_STATICEDGE)
            EndIf
        Case $GUI_EVENT_PRIMARYUP
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 18, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, 0)
            EndIf

    EndSwitch
WEnd

 

[QQruza]

А это какие-то системные настройки, что такая рамка появляется на GUICtrlCreateButton и ее цвет нельзя менять?

Сообщение автоматически объединено: 18 Июн 2020

Local $Form1 = GUICreate("Form1", 140, 100, 441, 172)
GUISetBkColor(0x111111)
Local $Label1 = GUICtrlCreateLabel("Кнопка", 10, 10, 120, 60, $SS_CENTERIMAGE + $SS_CENTER)
GUICtrlSetFont(-1, 18, 800, 0, "Arial")
GUICtrlSetBkColor(-1, 0x444444)
GUICtrlSetColor(-1, 0xffffff)
GUISetState()
Local $aInfC

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 16, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, $WS_EX_STATICEDGE)
            EndIf
        Case $GUI_EVENT_PRIMARYUP
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 18, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, 0)
            EndIf

    EndSwitch
WEnd

Не подскажете, как тут добавить ещё и изменение цвета элемента при наведении курсора?
Спасибо.

 

[joiner]

Спойлер

Local $aInfC, $flColor

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MOUSEMOVE
            $aInfC = GUIGetCursorInfo($Form1)
            If Not @error Then
                If $aInfC[4] = $Label1 Then
                    If Not $flColor Then
                        GUICtrlSetBkColor($Label1, 0x44444)
                        $flColor = 1
                    EndIf
                Else
                    If $flColor Then
                        GUICtrlSetBkColor($Label1, 0x444444)
                        $flColor = 0
                    EndIf
                EndIf
            EndIf
        Case $GUI_EVENT_PRIMARYDOWN
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 16, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, $WS_EX_STATICEDGE)
            EndIf
        Case $GUI_EVENT_PRIMARYUP
            $aInfC = GUIGetCursorInfo($Form1)
            If $aInfC[4] = $Label1 Then
                GUICtrlSetFont($Label1, 18, 800, 0, "Arial")
                GUICtrlSetStyle($Label1, $SS_CENTERIMAGE + $SS_CENTER, 0)
            EndIf

    EndSwitch
WEnd