[Элементы GUI] Выделение всех checkbox

[Vini]

Добрый день всем!
Имеется GUI с чекбоксами (более 10 штук). Как можно сделать ещё один чекбокс, который бы выделял (снимал выделение) все другие или группу? Или же можно кнопку (или две), для таких же целей

 

[CreatoR]

Re: [Элементы GUI] Выделение все cyeckbox

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test Script", 300, 400)

$iFirst_CB = GUICtrlCreateDummy()+1

$iTop = 20

For $i = 1 To 10
	GUICtrlCreateCheckbox("CheckBox" & $i, 20, $iTop)
	$iTop += 20
Next

$iLast_CB = GUICtrlCreateDummy()-1

$iCheckAll_CB = GUICtrlCreateCheckbox("Check All", 20, 270)

GUISetState(@SW_SHOW, $hGUI)

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $iCheckAll_CB
			$iState = GUICtrlRead($iCheckAll_CB)
			
			For $iCB = $iFirst_CB To $iLast_CB
				GUICtrlSetState($iCB, $iState)
			Next
	EndSwitch
WEnd

 

[Vini]

Всё отлично работает! Спасибо!

 

[CreatoR]

Vini [?]

Всё отлично работает

[info border=#0000ff float=left]На форуме принято помечать тему решенной после получения ответа на свой вопрос!
Вверху или внизу темы нажмите на ссылку такого вида:

Тема не решена[/info]