[Элементы GUI] восстановить состояние checkbox при включении скрипта

[andreitrane]

сделал сохранение состояния checkboxa, но сколько ни думал, не получилось чтобы при включении скрипта, тот читал ини файл и восстанавливал состояние checkbox'ов
помогите пожалуйста

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$sINI = @ScriptDir & '\configchb.ini'
$Form2 = GUICreate("Form2", 189, 108, 315, 226)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 8, 8, 81, 25)
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 8, 40, 81, 17)
$Checkbox3 = GUICtrlCreateCheckbox("Checkbox3", 8, 72, 81, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

		Case $Checkbox1


			if GUICtrlRead($Checkbox1) = $GUI_CHECKED Then
	IniWrite($sINI, "trololo", "chb1", "1")
	Else
	IniWrite($sINI, "trololo", "chb1", "0")
EndIf
		Case $Checkbox2


			if GUICtrlRead($Checkbox2) = $GUI_CHECKED Then
	IniWrite($sINI, "trololo", "chb2", "1")
	Else
	IniWrite($sINI, "trololo", "chb2", "0")
EndIf
		Case $Checkbox3


			if GUICtrlRead($Checkbox3) = $GUI_CHECKED Then
	IniWrite($sINI, "trololo", "chb3", "1")
	Else
	IniWrite($sINI, "trololo", "chb3", "0")
EndIf

	EndSwitch
WEnd

 

[CreatoR]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$sINI = @ScriptDir & '\configchb.ini'

$Form2 = GUICreate("Form2", 189, 108, 315, 226)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 8, 8, 81, 25)
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 8, 40, 81, 17)
$Checkbox3 = GUICtrlCreateCheckbox("Checkbox3", 8, 72, 81, 17)

_LoadSettings()

GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			_SaveSettings()
			Exit
	EndSwitch
WEnd

Func _LoadSettings()
	GUICtrlSetState($Checkbox1, IniRead($sINI, "trololo", "chb1", ""))
	GUICtrlSetState($Checkbox2, IniRead($sINI, "trololo", "chb2", ""))
	GUICtrlSetState($Checkbox3, IniRead($sINI, "trololo", "chb3", ""))
EndFunc

Func _SaveSettings()
	IniWrite($sINI, "trololo", "chb1", GUICtrlRead($Checkbox1))
	IniWrite($sINI, "trololo", "chb2", GUICtrlRead($Checkbox2))
	IniWrite($sINI, "trololo", "chb3", GUICtrlRead($Checkbox3))
EndFunc