Циклирование скрипта

[obeyme]

Как можно зациклить скрипт? Т.е он будет выполнять действие пока пользователь не нажмет, например, F11 и тогда скрипт закроется

 

[madmasles]

While ... WEnd
Do ... Until

 

[obeyme]

А можно с примером? Просто я новичок в Autoit. Вот мне нужен цикл для флудера. Т.е. нажимаешь F10 он флудит пока не нажмешь F11, например.

 

[madmasles]

obeyme [?]

А можно с примером?

Можно.
1.

Global $fWork, $iCount

HotKeySet('{F10}', '_Work_or_No')
HotKeySet('{F11}', '_Exit')
AdlibRegister('_My_Func', 1000)

While 1
	Sleep(100)
WEnd

Func _Work_or_No()
	$fWork = Not $fWork
	If Not $fWork Then $iCount = 0
EndFunc   ;==>_Work_or_No

Func _Exit()
	Exit
EndFunc   ;==>_Exit

Func _My_Func()
	If Not $fWork Then Return
	$iCount += 1
	ConsoleWrite($iCount & ' --> что-то делаем.' & @LF)
EndFunc   ;==>_My_Func

2.

Global $fWork, $iCount, $iStart

HotKeySet('{F10}', '_Work_or_No')
HotKeySet('{F11}', '_Exit')

$iStart = TimerInit()
While 1
	If TimerDiff($iStart) > 1000 Then
		_My_Func()
		$iStart = TimerInit()
	EndIf
	Sleep(100)
WEnd

Func _Work_or_No()
	$fWork = Not $fWork
	If Not $fWork Then $iCount = 0
EndFunc   ;==>_Work_or_No

Func _Exit()
	Exit
EndFunc   ;==>_Exit

Func _My_Func()
	If Not $fWork Then Return
	$iCount += 1
	ConsoleWrite($iCount & ' --> что-то делаем.' & @LF)
EndFunc   ;==>_My_Func

3.

Global $fWork, $iCount, $iStart, $fExit

HotKeySet('{F10}', '_Work_or_No')
HotKeySet('{F11}', '_Exit')

$iStart = TimerInit()
;While Not $fExit
Do
	If TimerDiff($iStart) > 1000 Then
		_My_Func()
		$iStart = TimerInit()
	EndIf
	Sleep(100)
Until $fExit
;WEnd
ConsoleWrite('exit' & @LF)

Func _Work_or_No()
	$fWork = Not $fWork
	If Not $fWork Then $iCount = 0
EndFunc   ;==>_Work_or_No

Func _Exit()
	$fExit = True
EndFunc   ;==>_Exit

Func _My_Func()
	If Not $fWork Then Return
	$iCount += 1
	ConsoleWrite($iCount & ' --> что-то делаем.' & @LF)
EndFunc   ;==>_My_Func

 

[obeyme]

Не могу разобраться :( что то по легче можно? Вот мой код:

MsgBox ( 64, 'Флудер', 'Нажми F10 чтобы начать флуд и F11 чтобы выйти из флудера')
HotKeySet('{F10}', 'Msg')
HotKeySet('{F11}', 'ext')
$text = InputBox('Флудер', 'Введите текст')
While 1
   Sleep(100)
Wend

Func ext()
   Exit
EndFunc

Func Msg()
   Send($text)
   Send('{enter}')
EndFunc

 

[Zaramot]

Вот, по твоему коду:

Global $var = 0

MsgBox ( 64, 'Флудер', 'Нажми F10 чтобы начать флуд и F11 чтобы выйти из флудера')

HotKeySet('{F10}', 'Msg')
HotKeySet('{F11}', 'ext')

$text = InputBox('Флудер', 'Введите текст')

While 1
   Sleep(100)
Wend

Func ext()
   $var = 1
EndFunc

Func Msg()
	Do
		Send($text)
		Send('{enter}')
	Until $var = 1
	Exit
EndFunc

 

[obeyme]

Zaramot, благодарю, плюсик твой. Вот что в итоге получилось:

MsgBox ( 64, 'Флудер', 'Нажми F10 чтобы начать флуд и F11 чтобы выйти из флудера')
HotKeySet('{F10}', 'Msg')
HotKeySet('{F11}', 'ext')
$c = 0
$text = InputBox('Флудер', 'Введите текст')
While 1
   Sleep(100)
Wend

Func ext()
   Exit
EndFunc

Func Msg()
    Do
        Send($text)
        Send('{enter}')
    Until $c = 1
EndFunc