Рисовать мышью в окне

passwd · 29 Апр 2016

Здравствуйте. Подскажите, возможно ли рисовать "от руки" в GUI? Чтобы как наподобие ручкой по бумаге или как в Paint мышью по экрану =)

InnI · 29 Апр 2016

passwd

возможно ли рисовать "от руки" в GUI?

Конечно, возможно. И даже штатными средствами

Код:

#include <GuiConstantsEx.au3>

GUICreate("")
$g = GUICtrlCreateGraphic(0, 0, 400, 400)
GUISetState()

Do
  $info = GUIGetCursorInfo()
  If Not @error And $info[2] Then
    GUICtrlSetGraphic($g, $GUI_GR_PIXEL, $info[0], $info[1])
    GUICtrlSetGraphic($g, $GUI_GR_REFRESH)
    Sleep(10)
  EndIf
Until GUIGetMsg() = -3

Но, если вы хотите рисовать "по-человечески", то вам нужно изучать GDI. А если ещё и на прозрачных картинках, то GDI+. Специалистов по графике на этом форуме - единицы. И я (пока) таковым не являюсь.

passwd · 30 Апр 2016

Спасибо! Вот нашел способ через GDI+

Код:

#include <GDIPlus.au3>
#include <misc.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)
$hwnd = GUICreate("Sample", 400, 400)
GUISetOnEvent(-3, "close")
GUISetState()

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND($hwnd)
_GDIPlus_GraphicsClear($graphics, 0xFFFFFFFF)
$pen = _GDIPlus_PenCreate(0xFF000000)

$dll = DllOpen("user32.dll")

Do
    If _IsPressed("01", $dll) And WinActive("Sample") Then
        $oldpos=MouseGetPos()
        _GDIPlus_GraphicsDrawRect($graphics,$oldpos[0],$oldpos[1],1,1,$pen)
        Do
            $pos = MouseGetPos()
            _GDIPlus_GraphicsDrawLine($graphics,$oldpos[0],$oldpos[1],$pos[0],$pos[1],$pen)
            $oldpos=$pos
        Until Not _IsPressed("01", $dll)
    EndIf
    Sleep(25)
Until False



Func close()
    _GDIPlus_PenDispose($pen)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

Можете подсказать как делать то же самое но на прозрачном фоне, чтобы можно было потом сохранить этот файл в PNG? =)

passwd · 2 Май 2016

Сделал окно, на котором рисовать - прозрачным. Но не получается сохранить рисунок.

Код:

#include <GDIPlus.au3>
#include <misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)
$hwnd = GUICreate("Sample", 400, 400, -1, -1, -1, $WS_EX_LAYERED)
$button1 = GUICtrlCreateButton("save",10,5)
GUICtrlSetOnEvent(-1, "save")
GUISetBkColor(0xABCDEF, $hwnd)
GUISetOnEvent(-3, "close")
GUISetState()
_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND($hwnd)
;_GDIPlus_GraphicsClear($graphics, 0xFFFFFFFF)
$pen = _GDIPlus_PenCreate(0xFF000000,3,0)
_WINAPI_SetLayeredWindowAttributes($hwnd, 0xABCDEF,255)

$dll = DllOpen("user32.dll")


Do
    If _IsPressed("01", $dll) And WinActive("Sample") Then
        $oldpos=MouseGetPos()
        _GDIPlus_GraphicsDrawRect($graphics,$oldpos[0],$oldpos[1],1,1,$pen)
        Do
            $pos = MouseGetPos()
            _GDIPlus_GraphicsDrawLine($graphics,$oldpos[0],$oldpos[1],$pos[0],$pos[1],$pen)
            $oldpos=$pos
        Until Not _IsPressed("01", $dll)
    EndIf
    Sleep(25)
Until False

Func save()
	$bitmap = _GDIPlus_BitmapCreateFromGraphics ( 400, 400, $graphics)
	$hCtxt = _GDIPlus_ImageGetGraphicsContext($bitmap)
	_GDIPlus_GraphicsSetSmoothingMode($hCtxt, 2)
	_GDIPlus_GraphicsDrawImage($graphics, $bitmap, 0, 0)
	_GDIPlus_ImageSaveToFile($bitmap, @DesktopDir & "\qqqqqqqqqqqq.png")
EndFunc;==>save

Func close()
    _GDIPlus_PenDispose($pen)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

Подскажите, почему сохраняется пустой прозрачный PNG?

passwd · 7 Май 2016

Решил рисовать на белом фоне а потом делать его прозрачным через ImageMagick такой командой:

Код:

RunWait(@ComSpec & " /c convert " & $drawing & " -transparent white " & $result)

firex · 7 Май 2016

passwd
Во-первых вы сами делаете фон непрозрачным:

Код:

_GDIPlus_GraphicsClear($graphics, 0xFFFFFFFF) ; Alpha = 0xFF (255)

Во-вторых рисовать прямо на поверхность окна не лучшая идея, так как при "перерисовке" фона ваши рисунки пропадут. Для примера задвиньте окно за пределы видимой области рабочего стола :smile:

Вам следует создать битмап размером с клиентскую область окна, далее все действия кистью отражать в битмап, который уже можно использовать для вывода в окно или сохранения в файл.

InnI · 7 Май 2016

passwd

Код:

#include <GDIPlus.au3>
#include <misc.au3>
#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

$hwnd = GUICreate("Sample", 400, 400, -1, -1, -1, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF, $hwnd)
_WINAPI_SetLayeredWindowAttributes($hwnd, 0xABCDEF, 255)
GUISetOnEvent(-3, "close")

$button1 = GUICtrlCreateButton("save",10,5)
GUICtrlSetOnEvent(-1, "save")
GUISetState()

GUIRegisterMsg($WM_ERASEBKGND, "WM_ERASEBKGND")
GUIRegisterMsg($WM_PAINT, "WM_ERASEBKGND")

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND($hwnd)
$bitmap = _GDIPlus_BitmapCreateFromGraphics(400, 400, $graphics)
$buffer = _GDIPlus_ImageGetGraphicsContext($bitmap)
_GDIPlus_GraphicsSetSmoothingMode($buffer, 2)
$pen = _GDIPlus_PenCreate(0xFFFF0000, 3)

$dll = DllOpen("user32.dll")

Do
    If _IsPressed("01", $dll) And WinActive("Sample") Then
        $oldpos = MouseGetPos()
        Do
            $pos = MouseGetPos()
            If $pos[0] <> $oldpos[0] Or $pos[1] <> $oldpos[1] Then
                _GDIPlus_GraphicsDrawLine($buffer, $oldpos[0], $oldpos[1], $pos[0], $pos[1], $pen)
                _GDIPlus_GraphicsDrawImage($graphics, $bitmap, 0, 0)
                $oldpos = $pos
            EndIf
            Sleep(10)
        Until Not _IsPressed("01", $dll)
    EndIf
    Sleep(10)
Until False

Func save()
    _GDIPlus_ImageSaveToFile($bitmap, @DesktopDir & "\qqqq.png")
EndFunc

Func close()
    _GDIPlus_PenDispose($pen)
    _GDIPlus_GraphicsDispose($buffer)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_Shutdown()
    DllClose($dll)
    Exit
EndFunc

Func WM_ERASEBKGND()
    _GDIPlus_GraphicsDrawImage($graphics, $bitmap, 0, 0)
    Return $GUI_RUNDEFMSG
EndFunc

Alofa · 7 Май 2016

InnI

Код:

DllClose()

InnI · 7 Май 2016

Alofa
Добавил :thanks:

inververs · 7 Май 2016

InnI

OffTopic:
что то пробую ваш код, и что бы начать рисовать в окне, нужно очень постараться. Курсор всегда проходит насквозь

InnI · 7 Май 2016

inververs

Курсор всегда проходит насквозь

Видимо, у вас отключено Aero (установлена упрощённая тема).
Добавлено:
Сообщение автоматически объединено: 8 Май 2016

Насколько я понял, функция _WINAPI_SetLayeredWindowAttributes() как раз для того и предназначена, чтобы делать области определённого цвета прозрачными для клика мышью. Но при включённом Aero на Win7 то ли ошибка присутствует, то ли особенность работы такая, но область становится прозрачной для клика только при одинаковых значениях компонент цвета. Например, 0xABABAB или 0x121212 и т.д. Если компоненты цветов разные, то, при включённом Aero, эта с виду прозрачная область клики не пропускает. Кстати, на Win10 клики проходят при любых значениях цветов, и там данный код не работает.
Добавлено:
Сообщение автоматически объединено: 8 Май 2016

passwd

Решил рисовать на белом фоне а потом делать его прозрачным через ImageMagick

В моём примере (Ответ #6) вы можете рисовать на фоне любого цвета с любой степенью прозрачности и даже на картинке. Также нет необходимости применять к окну стиль $WS_EX_LAYERED. Сохранение в PNG всё равно будет с прозрачным фоном, т.к. сохраняется bitmap из памяти, у которого фон не закрашен.

roman82101 · 20 Июл 2025

Работает на Win10

Код:

#NoTrayIcon
#include <Misc.au3>
#include <WINAPI.au3>
#include <GDIPlus.au3>
#include <GUIConstants.au3>


Opt('GUIOnEventMode', 1)
Opt('MouseCoordMode', 2)
$hGUI = GUICreate('Рисование в окне', 500, 250, -1, -1, -1, $WS_EX_LAYERED)
GUISetBkColor(0x000000)
_WINAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF, 255)
$iButtonSave = GUICtrlCreateButton('Сохранить', 375, 220)
GUICtrlSetBkColor(-1, 0xCCFFCC)
GUICtrlSetOnEvent(-1, '_Save')
$iButtonClear = GUICtrlCreateButton('Очистить', 440, 220)
GUICtrlSetBkColor(-1, 0xffc8c8)
GUICtrlSetOnEvent(-1, '_Clear')
GUISetOnEvent(-3, '_Exit')
GUISetState()
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hImage = _GDIPlus_BitmapCreateFromGraphics(500, 250, $hGraphic)
$hBufferGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)
_GDIPlus_GraphicsSetSmoothingMode($hBufferGraphics, 2)
$hPen = _GDIPlus_PenCreate(0xaa0000ff, 4) ;Если 6 символов, то в начале добавить "aa"
$hDLL = DllOpen('user32.dll')

Do
 If _IsPressed('01', $hDLL) And WinActive($hGUI) Then
  $aOldPos = MouseGetPos()
  Do
   $aPos = MouseGetPos()
   If $aPos[0] <> $aOldPos[0] Or $aPos[1] <> $aOldPos[1] Then
    _GDIPlus_GraphicsDrawLine($hBufferGraphics, $aOldPos[0], $aOldPos[1], $aPos[0], $aPos[1], $hPen)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)
    $aOldPos = $aPos
   EndIf
   Sleep(10)
  Until Not _IsPressed('01', $hDLL)
 EndIf
 Sleep(10)
Until False


Func _Save()
 _GDIPlus_ImageSaveToFile($hImage, @ScriptDir&'\Image-'&@MIN&'.png')
 GUIDelete($hGUI)
 _Exit()
EndFunc ;==>_Save()

Func _Clear()
 _GDIPlus_GraphicsClear($hGraphic, 0x000000)
 _GDIPlus_GraphicsClear($hBufferGraphics, 0x000000)
 GUICtrlSetState($iButtonSave, $GUI_SHOW)
 GUICtrlSetState($iButtonClear, $GUI_SHOW)
EndFunc ;==>_Clear()

Func _Exit()
 _GDIPlus_PenDispose($hPen)
 _GDIPlus_GraphicsDispose($hBufferGraphics)
 _GDIPlus_GraphicsDispose($hGraphic)
 _GDIPlus_BitmapDispose($hImage)
 _GDIPlus_Shutdown()
 DllClose($hDLL)
 Exit
EndFunc ;==>_Exit()

Автор темы	Похожие темы	Форум	Ответы	Дата
F	Распарсить файл рисунка из линий и нарисовать (например в paint) используя 3 цвета	Стол заказов	3	29 Мар 2023
M	Как перерисовать окно после _GUIImageList_Draw	Общие вопросы по AutoIt	0	1 Дек 2018
M	Нарисовать текст на экране	GUI - Графический интерфейс пользователя	18	10 Авг 2017
P	Как нарисовать CheckBox на заголовке ListView	GUI - Графический интерфейс пользователя	6	2 Ноя 2016
	[Элементы GUI] Как нарисовать точку в окне GUI и эффективно ее двигать?	Общие вопросы по AutoIt	10	24 Сен 2015

Поиск

Поиск

Рисовать мышью в окне

passwd

Новичок

InnI

AutoIT Гуру

passwd

Новичок

passwd

Новичок

passwd

Новичок

firex

AutoIT Гуру

InnI

AutoIT Гуру

Alofa

Гость

InnI

AutoIT Гуру

inververs

AutoIT Гуру

InnI

AutoIT Гуру

roman82101

Новичок