Блокировать или отключит клавиатуру на время

hikki · 13 Окт 2009

Вопрос как?
Нужно на время работы функции отключить клавиатуру или ввод с нее или еще как ее заблочить.
Требуется для работы бота, по какимто причинам в игре не работает BlockInput и BlockInputEx.

http://autoit-script.ru/index.php/topic,347.0.html
Надеюсь не сильно нарушаю правила форума, создавая дублирующую тему. Вроде это не только ботов касается, да и многие профи могут не заглядывать в тот раздел.

Yashied · 14 Окт 2009

Можно так.

Код:

#Include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
#Include <WindowsConstants.au3>

Global $Lock = False

$hDll = DllCallbackRegister('_KbdHook', 'long', 'int;wparam;lparam')
$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hDll), _WinAPI_GetModuleHandle(0), 0)

GUICreate('MyGUI', 200, 59)
$Check = GUICtrlCreateCheckbox('Lock keyboard', 20, 20, 160, 19)
GUISetState()

While 1
	$Msg = GUIGetMsg()
	Switch $Msg
		Case $GUI_EVENT_CLOSE
			ExitLoop
		Case $Check
			_KbdLock(BitAND(GUICtrlRead($Check), $GUI_CHECKED))
	EndSwitch
WEnd

Func _KbdLock($fLock)
	$Lock = $fLock
EndFunc   ;==>_KbdLock

Func _KbdHook($iCode, $wParam, $lParam)
	If ($iCode > -1) And ($Lock) Then
		Switch $wParam
			Case $WM_KEYDOWN, $WM_SYSKEYDOWN
				Return -1
		EndSwitch
	EndIf
	Return _WinAPI_CallNextHookEx($hHook, $iCode, $wParam, $lParam)
EndFunc   ;==>_KbdHook

Func OnAutoItExit()
	_WinAPI_UnhookWindowsHookEx($hHook)
	DllCallbackFree($hDll)
EndFunc   ;==>OnHotKeyExit

CreatoR · 14 Окт 2009

hikki [?]

Надеюсь не сильно нарушаю правила форума, создавая дублирующую тему.

Нету такого «не сильное нарушение правил», нарушение есть нарушение. А то что ты знаешь об этом не делает его облегчённым, даже наоборот.

по какимто причинам в игре не работает BlockInput и BlockInputEx

Пример использования (последнего)?

Yashied [?]

Можно так.

Так в _BlockInputEx используется этот же хук :smile:

hikki · 14 Окт 2009

Но тем не менее здесь решение нашлось. Хотя возможно что я плохо ковырял BlockInputEx, но тем не менее решение есть и оно работает.

Автор темы	Похожие темы	Форум	Ответы	Дата
	Как заблокировать движение мыши по Y	Общие вопросы по AutoIt	2	7 Июл 2023
	Мышь, клавиатура Как блокировать ввод, оставляя его рабочим для скрипта AutoIt?	Общие вопросы по AutoIt	5	24 Мар 2022
	[Мышь, клавиатура] Как заблокировать клавишу мыши в определенном окне?	Общие вопросы по AutoIt	0	22 Апр 2018
D	Разблокировать компьютер	Общие вопросы по AutoIt	2	18 Апр 2017
	Как заблокировать зум по ctrl колесико мыши в определенном окне?	Автоматизация IE и Web-интерфейса	3	28 Фев 2017

Поиск

Поиск

Блокировать или отключит клавиатуру на время

hikki

Продвинутый

Yashied

Модератор

CreatoR

Must AutoIt!

hikki

Продвинутый