↑  ←  Описание функции

_WinAPI_SetSysColors

Устанавливает цвета отображаемых элементов системы (частей окна и т.д.)

#include <WinAPI.au3>
_WinAPI_SetSysColors($vElements, $vColors)

Параметры

$vElements Единственный элемент или массив элементов
$vColors Единственный цвет или массив, содержащий цвета

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Смотрите индексы элементов и требования в функции _WinAPI_GetSysColor.

См. также

_WinAPI_GetSysColor

См. также

Искать SetSysColors в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $aElements[2] = [$COLOR_ACTIVECAPTION, $COLOR_GRADIENTACTIVECAPTION]
    ; Красный и жёлтый
    Local $aColors[2] = [255, 65535], $aSaveColors[2]

    DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0) ; отключение темы для окна

    GUICreate("Мой GUI", 300, 200)

    ; Сохранение текущего цвета
    $aSaveColors[0] = _WinAPI_GetSysColor($COLOR_ACTIVECAPTION)
    $aSaveColors[1] = _WinAPI_GetSysColor($COLOR_GRADIENTACTIVECAPTION)

    ; Устанавливает новый цвет
    _WinAPI_SetSysColors($aElements, $aColors)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete()

    ; Восстановление предыдущих установок
    _WinAPI_SetSysColors($aElements, $aSaveColors)

    Exit

EndFunc