_WinAPI_EnumDisplayDevices
Получает информацию об устройстве отображения в системе
#include <WinAPI.au3>
_WinAPI_EnumDisplayDevices($sDevice, $iDevNum)
Параметры
| $sDevice | Device name. If blank, the function returns information for the display adapters on the machine based on iDevNum. |
| $iDevNum |
Zero based index value that specifies the display device of interest |
Возвращаемое значение
| Успех: | Возвращает массив следующего формата: |
| $aDevice[0] - True | |
| $aDevice[1] - Either the adapter device or the monitor device | |
| $aDevice[2] - Either a description of the adapter or the monitor | |
| $aDevice[3] - Device state flags: | |
| 1 - The device is part of the desktop | |
| 2 - The primary desktop is on the device | |
| 4 - Represents a pseudo device used to mirror application drawing for remoting | |
| 8 - The device is VGA compatible | |
| 16 - The device is removable; it cannot be the primary display | |
| 32 - The device has more display modes than its output devices support | |
| $aDevice[4] - reserved | |
| Ошибка: | Устанавливает @error |
См. также
Искать EnumDisplayDevices в библиотеке MSDNПример
#include <WinAPI.au3>
_Main()
Func _Main()
Local $aDevice, $i = 0, $text
While 1
$aDevice = _WinAPI_EnumDisplayDevices("", $i)
If Not $aDevice[0] Then ExitLoop
If $aDevice[1]&$aDevice[2]&$aDevice[4] = '' Then ExitLoop
$text = "Успешно? " & $aDevice[0] & @LF
$text &= "Устройство (Адаптер или монитор): " & $aDevice[1] & @LF
$text &= "Описание (Адаптер или монитор): " & $aDevice[2] & @LF
$text &= "Флаг состояния устройства: " & $aDevice[3] & @LF
If BitAND($aDevice[3], 32) Then $text &= @TAB & "- Устройство имеет больше режимов отображения, чем поддерживается устройством вывода" & @LF
If BitAND($aDevice[3], 16) Then $text &= @TAB & "- Устройство является съемным; оно не может быть основным монитором" & @LF
If BitAND($aDevice[3], 8) Then $text &= @TAB & "- Устройство является VGA совместимый" & @LF
If BitAND($aDevice[3], 4) Then $text &= @TAB & "- Псевдо-устройство, used to mirror application drawing for remoting" & @LF
If BitAND($aDevice[3], 2) Then $text &= @TAB & "- Основной устройство" & @LF
If BitAND($aDevice[3], 1) Then $text &= @TAB & "- Устройство является частью компьютера" & @LF
$text &= "Идентификатор Plug and Play: " & $aDevice[4] & @LF
MsgBox(4096, "", $text)
$i += 1
WEnd
EndFunc ;==>_Main