Функция _IEDocWriteHTML

_IEDocWriteHTML

Заменяет содержимое всего HTML-документа.

#include <IE.au3>
_IEDocWriteHTML(ByRef $o_object, $s_html)

Параметры

$o_object	Переменная объекта InternetExplorer.Application, объекта Окна или Фрейма (области)
$s_html	HTML-код для записи в документ

Возвращаемое значение

Успех:	Возвращает -1
Ошибка:	Возвращает 0 и устанавливает @error
@error:	0 ($_IEStatus_Success) = Нет ошибок
	1 ($_IEStatus_GeneralError) = Общая ошибка
	3 ($_IEStatus_InvalidDataType) = Неверный тип данных
	4 ($_IEStatus_InvalidObjectType) = Неверный тип объекта
	6 ($_IEStatus_LoadWaitTimeout) = Тайм-аут ожидания загрузки
	8 ($_IEStatus_AccessIsDenied) = Отказано в доступе
	9 ($_IEStatus_ClientDisconnected) = Клиент отключен
@extended:	Содержит номер неверного параметра

Примечания

Эта функция полностью заменяет содержимое документа в браузере или фрейме (области). Функция может использоваться при создании новой страницы с необходимым HTML и JavaScript.

Иногда после записи для обновления страницы необходимо выполнить _IEAction($oIE, "refresh") (например после создания FRAMESET).

См. также

_IEDocReadHTML, _IELoadWait

Пример

; Пример 1 - Создаёт пустой браузер, записывает в него HTML-код, в данном случае
;    фреймы FRAMESET, и далее обновляет содержимое каждого фрейма

#include <IE.au3>
$oIE = _IECreate () ; Создаёт пустой браузер
$sHTML = ""
$sHTML &= "<HTML>" & @CR
$sHTML &= "<HEAD>" & @CR
$sHTML &= "<TITLE>_IE_Example('frameset')</TITLE>" & @CR
$sHTML &= "</HEAD>" & @CR
$sHTML &= "<FRAMESET rows='25,200'>" & @CR
$sHTML &= " <FRAME NAME=Top SRC=about:blank>" & @CR
$sHTML &= " <FRAMESET cols='100,500'>" & @CR
$sHTML &= "   <FRAME NAME=Menu SRC=about:blank>" & @CR
$sHTML &= "   <FRAME NAME=Main SRC=about:blank>" & @CR
$sHTML &= " </FRAMESET>" & @CR
$sHTML &= "</FRAMESET>" & @CR
$sHTML &= "</HTML>"
_IEDocWriteHTML ($oIE, $sHTML) ; Записывает вышеуказанный HTML-код
_IEAction ($oIE, "refresh") ; Обновляет HTML-страницу
; Получает объект-ссылки на фреймы
Local $oFrameTop = _IEFrameGetObjByName ($oIE, "Top")
Local $oFrameMenu = _IEFrameGetObjByName ($oIE, "Menu")
Local $oFrameMain = _IEFrameGetObjByName ($oIE, "Main")
; Записывает в каждый фрейм
_IEBodyWriteHTML ($oFrameTop, '$oFrameTop = _IEFrameGetObjByName($oIE, "Top")')
_IEBodyWriteHTML ($oFrameMenu, '$oFrameMenu = _IEFrameGetObjByName($oIE, "Menu")')
_IEBodyWriteHTML ($oFrameMain, '$oFrameMain = _IEFrameGetObjByName($oIE, "Main")')