↑  ←  Описание функции

_GUIScrollBars_GetScrollPos

Retrieves the current position of the scroll box (thumb) in the specified scroll bar

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollPos($hWnd, $nBar)

Параметры

$hWnd Дескриптор окна
$nBar Тип полосы прокрутки. Этот параметр может быть одним из следующих значений:
    $SB_CTL - Retrieves the position of the scroll box in a scroll bar control. Параметр $hWnd должен быть дескриптором ScrollBars.
    $SB_HORZ - Retrieves the position of the scroll box in a window's standard horizontal scroll bar
    $SB_VERT - Retrieves the position of the scroll box in a window's standard vertical scroll bar.

Возвращаемое значение

Успех:Current position of the scroll box
Ошибка:Возвращает -1

Примечания

Для выше указанных констант необходим ScrollBarConstants.au3

См. также

_GUIScrollBars_SetScrollInfoPos

См. также

Искать GetScrollPos в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GuiScrollBars.au3>
#include <ScrollBarConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $GUIMsg, $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $iMemo = GUICtrlCreateEdit("", 2, 2, 380, 380, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState()

    _GUIScrollBars_Init($hGUI)

    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_HORZ, 10)
    MemoWrite("Scroll Pos Horizontal: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_HORZ))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_HORZ, 0)
    MemoWrite("Scroll Pos Horizontal: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_HORZ))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_VERT, 20)
    MemoWrite("Scroll Pos Vertical: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_VERT))
    Sleep(1000)
    _GUIScrollBars_SetScrollInfoPos($hGUI, $SB_VERT, 0)
    MemoWrite("Scroll Pos Vertical: " & _GUIScrollBars_GetScrollPos($hGUI, $SB_VERT))

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite