↑  ←  Описание функции

_GUIScrollBars_EnableScrollBar

Включает или отключает (делает серым) ScrollBars

#include <GuiScrollBars.au3>
_GUIScrollBars_EnableScrollBar($hWnd [, $wSBflags = $SB_BOTH [, $wArrows = $ESB_ENABLE_BOTH]])

Параметры

$hWnd Дескриптор окна
$wSBflags [необязательный] Тип полосы прокрутки. Этот параметр может быть одним из следующих значений:
    $SB_BOTH - Включает или отключает стрелки на горизонтальной и вертикальной полосе прокрутки, связанные с указанным окном.
    $SB_CTL - Указывает, что полоса прокрутки является ScrollBars. Параметр $hWnd должен быть дескриптором ScrollBars.
    $SB_HORZ - Включает или отключает стрелки на горизонтальной полосе прокрутки, связанные с указанным окном.
    $SB_VERT - Включает или отключает стрелки на вертикальной полосе прокрутки, связанные с указанным окном.
$wArrows [необязательный] Указывает, будет ли стрелки полосы прокрутки доступны или недоступны, и какие именно стрелки.
    Этот параметр может быть одним из следующих значений
    $ESB_DISABLE_BOTH - Отключает обе стрелки на полосе прокрутки.
    $ESB_DISABLE_DOWN - Отключает стрелку вниз на вертикальной полосе прокрутки.
    $ESB_DISABLE_LEFT - Отключает стрелку влево на горизонтальной полосе прокрутки.
    $ESB_DISABLE_LTUP - Отключает стрелку влево на горизонтальной полосе прокрутки или стрелку вверх на вертикальной полосе прокрутки.
    $ESB_DISABLE_RIGHT - Отключает стрелку вправо на горизонтальной полосе прокрутки.
    $ESB_DISABLE_RTDN - Отключает стрелку вправо на горизонтальной полосе прокрутки или стрелку вниз на вертикальной полосе прокрутки.
    $ESB_DISABLE_UP - Отключает стрелку вверх на вертикальной полосе прокрутки.
    $ESB_ENABLE_BOTH - Включает обе стрелки на полосе прокрутки.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Для выше указанных констант необходим ScrollBarConstants.au3

См. также

_GUIScrollBars_ShowScrollBar

См. также

Искать EnableScrollBar в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiScrollBars.au3>
#include <ScrollBarConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $GUIMsg, $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState()

    _GUIScrollBars_Init($hGUI)

    MemoWrite("Disable down arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_DOWN))
    Sleep(3000)
    MemoWrite("Disable up arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_UP))
    Sleep(3000)
    MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_ENABLE_BOTH))
    Sleep(3000)
    MemoWrite("Disable left arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_LEFT))
    Sleep(3000)
    MemoWrite("Disable right arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_RIGHT))
    Sleep(3000)
    MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_ENABLE_BOTH))

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE;, $nExititem
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite