_GUIImageList_SetBkColor
Устанавливает цвет фона для списка изображений
#include <GuiImageList.au3>
_GUIImageList_SetBkColor($hWnd, $iClrBk)
Параметры
| $hWnd | Дескриптор ImageList |
| $iClrBk |
Устанавливаемый цвет фона. Этот параметр может быть значением $CLR_NONE; в этом случае, изображения становятся прозрачными с помощью маски. |
Возвращаемое значение
| Успех: | Возвращает предыдущий цвет фона |
| Ошибка: | $CLR_NONE |
См. также
_GUIImageList_GetBkColorПример
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
_Main()
Func _Main()
Local $listview, $hImage
Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("Устанавливает цвет фона для списка изображений", 400, 300)
$listview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
GUISetState()
; Загружает изображения
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUICtrlListView_SetImageList($listview, $hImage, 1)
MsgBox(4160, "Информация", "Цвет фона: " & _GUIImageList_GetBkColor($hImage))
_GUIImageList_SetBkColor($hImage, 0x0000FF)
MsgBox(4160, "Информация", "Цвет фона: " & _GUIImageList_GetBkColor($hImage))
; Добавляет колонки
_GUICtrlListView_AddColumn($listview, "Колонка 1", 120)
_GUICtrlListView_AddColumn($listview, "Колонка 2", 100)
_GUICtrlListView_AddColumn($listview, "Колонка 3", 100)
; Добавляет пункты
_GUICtrlListView_AddItem($listview, "Стр 1: Кол 1", 0)
_GUICtrlListView_AddSubItem($listview, 0, "Стр 1: Кол 2", 1, 1)
_GUICtrlListView_AddSubItem($listview, 0, "Стр 1: Кол 3", 2, 2)
_GUICtrlListView_AddItem($listview, "Стр 2: Кол 1", 1)
_GUICtrlListView_AddSubItem($listview, 1, "Стр 2: Кол 2", 1, 2)
_GUICtrlListView_AddItem($listview, "Стр 3: Кол 1", 2)
_GUICtrlListView_AddItem($listview, "Стр 4: Кол 1", 3)
_GUICtrlListView_AddItem($listview, "Стр 5: Кол 1", 4)
_GUICtrlListView_AddSubItem($listview, 4, "Стр 5: Кол 2", 1, 3)
_GUICtrlListView_AddItem($listview, "Стр 6: Кол 1", 5)
_GUICtrlListView_AddSubItem($listview, 5, "Стр 6: Кол 2", 1, 4)
_GUICtrlListView_AddSubItem($listview, 5, "Стр 6: Кол 3", 2, 3)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main