↑  ←  Описание функции

_GUIImageList_Duplicate

Создает копию существующего списка изображений

#include <GuiImageList.au3>
_GUIImageList_Duplicate($hWnd)

Параметры

$hWnd Дескриптор ImageList

Возвращаемое значение

Успех:Возвращает дескриптор новой копии списка изображений
Ошибка:Возвращает 0

Примечания

Вся информация, содержащаяся в первоначальном списке изображений для нормальных изображений, копируется в новый список изображений.
Оверлейные (наложенные поверх) изображения не копируются.

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $listview, $hImage
    Local $Wow64 = ""
    If @autoitx64 Then $Wow64 = "\Wow6432Node"
    Local $AutoItDir = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir")
    Local $hImage2

    GUICreate("ImageList Duplicate", 410, 300)
    $listview = GUICtrlCreateListView("", 2, 2, 404, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    GUISetState()

    ; Создаёт список изображений с изображениями
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v9.ico")
    _GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v10.ico")
    $hImage2 = _GUIImageList_Duplicate($hImage)
    _GUICtrlListView_SetImageList($listview, $hImage2, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($listview, "Колонка 1", 100, "Left", 0)
    _GUICtrlListView_AddColumn($listview, "Колонка 2", 100, "Left", 1)
    _GUICtrlListView_AddColumn($listview, "Колонка 3", 100, "Left", 2)
    _GUICtrlListView_AddColumn($listview, "Колонка 4", 100)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main