↑  ←  Описание функции

_GUICtrlTreeView_SetState

Устанавливает состояние указанного пункта

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetState($hWnd, $hItem [, $iState = 0 [, $iSetState = 0]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта
$iState [необязательный] Новое состояние пункта, может быть одно или комбинацией следующих значений:
    $TVIS_SELECTED - Делает пункт выделенным
    $TVIS_CUT - Устанавливает пункт как вырезанный, в пределах операции вырезать и вставить
    $TVIS_DROPHILITED - Устанавливает пункт как объект операции перетаскивания (drag-and-drop)
    $TVIS_BOLD - Делает пункт с жирным шрифтом
    $TVIS_EXPANDED - Разворачивает пункт
    $TVIS_EXPANDEDONCE - Устанавливает, что пункт с дочерними пунктами раскрыт хотя бы один раз
    $TVIS_EXPANDPARTIAL - Set item as partially expanded
$iSetState [необязательный] Устанавливает или снимает состояние
True - устанавливает состояние пункта
False - удаляет состояние пункта

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Значения состояния могут быть сложены вместе, например BitOr($TVIS_SELECTED, $TVIS_BOLD).

См. также

_GUICtrlTreeView_GetState

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $hImage, $iImage, $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Устанавливает состояние", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $iImage = Random(0, 5, 1)
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x), $iImage, $iImage)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] Дочерний", $y), $iImage, $iImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SetState($hTreeView, $hItem[$iRand], $TVIS_CUT)
    MsgBox(4160, "Информация", StringFormat("Состояние для индекса %d : %s", $iRand, _GUICtrlTreeView_GetState($hTreeView, $hItem[$iRand])))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main