_GUICtrlTreeView_SetChecked
Устанавливает состояние Checkbox (галочки в квадрате)
#include <GuiTreeView.au3>
_GUICtrlTreeView_SetChecked($hWnd, $hItem [, $fCheck = True])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hItem |
Дескриптор пункта |
| $fCheck |
[необязательный] Значение, устанавливающее состояние: True - Устанавливает галочку False - Снимает галочку |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlTreeView_GetCheckedПример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hItem[6], $hRandomItem, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("Устанавливает галочку", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To UBound($hItem) - 1
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$hRandomItem = Random(0, UBound($hItem) - 1, 1)
MsgBox(4160, "Информация", StringFormat("Пункт %d с галочкой? %s", $hRandomItem, _GUICtrlTreeView_GetChecked($hTreeView, $hItem[$hRandomItem])))
_GUICtrlTreeView_SetChecked($hTreeView, $hItem[$hRandomItem])
MsgBox(4160, "Информация", StringFormat("Пункт %d с галочкой? %s", $hRandomItem, _GUICtrlTreeView_GetChecked($hTreeView, $hItem[$hRandomItem])))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main