↑  ←  Описание функции

_GUICtrlTreeView_GetVisibleCount

Возвращает количество полностью видимых в данный момент пунктов в TreeView

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetVisibleCount($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Возвращает максимальное количество полностью видимых пунктов

Примечания

Количество полностью видимых пунктов может быть больше, чем количество пунктов в TreeView. Вычисление выполняется путём деления высоты TreeView на высоту пункта. Обратите внимание, что возвращается количество пунктов, которые являются полностью видимыми, а не частично. Если вы видите 20 пунктов и частично еще один пункт, то возвращается 20, а не 21.

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("Количество видимых пунктов", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 99
        _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "Информация", "Количество полностью видимых пунктов: " & _GUICtrlTreeView_GetVisibleCount($hTreeView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main