_GUICtrlTreeView_GetText
Возвращает текст пункта
#include <GuiTreeView.au3>
_GUICtrlTreeView_GetText($hWnd [, $hItem = 0])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hItem |
[необязательный] Идентификатор или дескриптор пункта |
Возвращаемое значение
| Успех: | Возвращает текст пункта |
| Ошибка: | Возвращает пустую строку |
См. также
_GUICtrlTreeView_SetText, _GUICtrlTreeView_GetTreeПример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hItem[10], $hChildItem[30], $iYItem = 0, $iRand, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("Получить текст пункта", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 9
$hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
_GUICtrlTreeView_SetStateImageIndex($hTreeView, $hItem[$x], 1)
For $y = 1 To 3
$hChildItem[$iYItem] = _GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] Дочерний", $y))
_GUICtrlTreeView_SetStateImageIndex($hTreeView, $hChildItem[$iYItem], 1)
$iYItem += 1
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$iRand = Random(0, 9, 1)
_GUICtrlTreeView_SelectItem($hTreeView, $hItem[$iRand])
MsgBox(4160, "Информация", StringFormat("Текст пункта с индексом %d: %s", $iRand, _GUICtrlTreeView_GetText($hTreeView, $hItem[$iRand])))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main