↑  ←  Описание функции

_GUICtrlTreeView_GetPrev

Возвращает дескриптор предыдущего пункта, перед указанным

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetPrev($hWnd, $hItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта

Возвращаемое значение

Успех:Возвращает дескриптор предыдущего пункта
Ошибка:Возвращает 0

Примечания

Если указанный пункт является первым в корне дерева, то функция возвращает 0, иначе возвращает дескриптор предыдущего пункта включая невидимые и дочерние. Чтобы получить предыдущий пункт на том же уровне, что и указанный пункт используйте _GUICtrlTreeView_GetPrevChild. Чтобы получить предыдущий видимый пункт, используйте _GUICtrlTreeView_GetPrevVisible.

См. также

_GUICtrlTreeView_GetNext, _GUICtrlTreeView_GetPrevChild, _GUICtrlTreeView_GetPrevVisible

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $iYItem = 0, $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Получить предыдущий пункт", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 3
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $iYItem), $hItem[$x])
            $iYItem += 1
        Next
    Next
    $hItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", 4), $hTreeView)
    For $x = 5 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $iYItem), $hItem[$x])
            $iYItem += 1
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[$iRand]) ; выделяет пункт
    MsgBox(4160, "Информация", StringFormat("Дескриптор предыдущего пункта для индекса %d: %s", $iRand, _GUICtrlTreeView_GetPrev($hTreeView, $hItem[$iRand])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetPrev($hTreeView, $hItem[$iRand])) ; выделяет предыдущий

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main