↑  ←  Описание функции

_GUICtrlTreeView_GetLastChild

Возвращает дескриптор последнего дочернего пункта указанного родительского пункта

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetLastChild($hWnd, $hItem)

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор родительского пункта

Возвращаемое значение

Успех:Возвращает дескриптор последнего дочернего пункта
Ошибка:Возвращает 0

См. также

_GUICtrlTreeView_GetFirstChild, _GUICtrlTreeView_GetNextChild, _GUICtrlTreeView_GetPrevChild

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $iYIndex = 0, $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Получить последний дочерний", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = $iYIndex To $iYIndex + 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
        Next
        $iYIndex += 3
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(0, 9, 1)
    MsgBox(4160, "Информация", StringFormat("Дескриптор последнего дочернего пункта в родительском пункте %d : %s", $iRand, _GUICtrlTreeView_GetLastChild($hTreeView, $hItem[$iRand])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetLastChild($hTreeView, $hItem[$iRand]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main