↑  ←  Описание функции

_GUICtrlTreeView_DisplayRectEx

Возвращает прямоугольник, ограничивающий пункт TreeView

#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRectEx($hWnd, $hItem [, $fTextOnly = False])

Параметры

$hWnd Дескриптор или идентификатор элемента
$hItem Дескриптор пункта, прямоугольник которого будет возвращён
$fTextOnly [необязательный] Если True, то ограничивающий прямоугольник содержит только текст пункта. Иначе, содержит всю строку, которую занимает пункт.

Возвращаемое значение

Успех:Возвращает структуру $tagRECT, которая содержит ограничивающий прямоугольник. Координаты относительно левого верхнего угла TreeView.
Ошибка:Устанавливает @error

См. также

_GUICtrlTreeView_DisplayRect, $tagRECT

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[6], $hImage, $tRect, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("Границы пункта", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x + 1), $x, $x)
    Next
    $tRect = _GUICtrlTreeView_DisplayRectEx($hTreeView, $hItem[2])
    MsgBox(4160, "Информация", StringFormat('Прямоугольник ограничивающий "[03] Пункт" : [%d, %d, %d, %d]', DllStructGetData($tRect, "Left"), _
            DllStructGetData($tRect, "Top"), DllStructGetData($tRect, "Right"), DllStructGetData($tRect, "Bottom")))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main