↑  ←  Описание функции

_GUICtrlToolbar_SetPadding

Устанавливает отступы внутри кнопок

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetPadding($hWnd, $iCX, $iCY)

Параметры

$hWnd Дескриптор элемента
$iCX Горизонтальный отступ в пикселях
$iCY Вертикальный отступ в пикселях

Возвращаемое значение

Успех: Возвращает предыдущие горизонтальный отступ в младшем слове и вертикальный отступ в старшем слове

Примечания

Отступы используются для создания пустой области между краем кнопки и изображение кнопки и/или текста. Горизонтальный отступ устанавливает отступы слева и справа, а вертикальный - сверху и снизу. Отступы применяется только к кнопкам, которые имеют стиль $TBSTYLE_AUTOSIZE.

См. также

_GUICtrlToolbar_GetPadding

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aPad
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 76, 396, 222, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Устанавливает отступ Toolbar
    _GUICtrlToolbar_SetPadding($hToolbar, 40, 40)

    ; Добавляет стандартный системный bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Показывает отступ Toolbar
    $aPad = _GUICtrlToolbar_GetPadding($hToolbar)
    MemoWrite("Горизонтальный отступ : " & $aPad[0])
    MemoWrite("Вертикальный отступ ..: " & $aPad[1])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite