_GUICtrlToolbar_SetBitmapSize
Устанавливает размер bitmapped изображений, добавленных в Toolbar
#include <GuiToolBar.au3>
_GUICtrlToolbar_SetBitmapSize($hWnd, $iWidth, $iHeight)
Параметры
| $hWnd | Дескриптор элемента |
| $iWidth |
Высота bitmapped изображений в пикселях |
| $iHeight |
Ширина bitmapped изображений в пикселях |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
Примечания
Размер можно задать только перед добавлением каких либо bitmaps в Toolbar. Если приложение явно не задаёт размеры bitmap, то по умолчанию размер 16 на 15 пиксель.Пример
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aStrings[4]
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
GUISetState()
; Добавляет стандартный системный bitmaps
_GUICtrlToolbar_SetBitmapSize($hToolbar, 24, 24)
_GUICtrlToolbar_LoadImages($hToolbar, $IDB_STD_LARGE_COLOR)
; Добавляет строки
$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Новая")
$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Открыть")
$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Сохранить")
$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Справка")
; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main