↑  ←  Описание функции

_GUICtrlToolbar_GetMetrics

Возвращает метрику панели инструментов

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetMetrics($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Ширина отступа внутри кнопок
        [1] - Высота отступа внутри кнопок
        [2] - Ширина интервала между кнопками
        [3] - Высота интервала между кнопками

Примечания

Минимальная ОС - Windows XP.

См. также

_GUICtrlToolbar_SetMetrics

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aMetrics
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 76, 396, 222, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Устанавливает метрику Toolbar
    _GUICtrlToolbar_SetMetrics($hToolbar, 40, 40, 30, 4)

    ; Добавляет стандартный системный bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; GUISetState(@SW_LOCK)
    ; _GUICtrlToolbar_SetMetrics($hToolbar, 1, 2, 30, 4)
    ; GUISetState(@SW_UNLOCK)

    ; Показывает метрику Toolbar
    $aMetrics = _GUICtrlToolbar_GetMetrics($hToolbar)
    MemoWrite("Ширина отступа кнопки  : " & $aMetrics[0])
    MemoWrite("Высота отступа кнопки  : " & $aMetrics[1])
    MemoWrite("Ширина интервала кнопок: " & $aMetrics[2])
    MemoWrite("Высота интервала кнопок: " & $aMetrics[3])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite