_GUICtrlToolbar_CommandToIndex
Возвращает индекс кнопки на основе идентификатора
#include <GuiToolBar.au3>
_GUICtrlToolbar_CommandToIndex($hWnd, $iCommandID)
Параметры
| $hWnd | Дескриптор элемента |
| $iCommandID |
Идентификатор кнопки |
Возвращаемое значение
| Успех: | Возвращает индекс кнопки, отсчёт от 0 |
| Ошибка: | Возвращает -1 |
См. также
_GUICtrlToolbar_IndexToCommandПример
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hGUI, $hToolbar, $iIndex
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
GUISetState()
; Добавляет стандартный системный bitmaps
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Показывает индекс кнопки "Save"
$iIndex = _GUICtrlToolbar_CommandToIndex($hToolbar, $idSave)
MsgBox(4096, "Информация", 'Индекс кнопки "Save" : ' & $iIndex & @LF & _
'Командный идентификатор кнопки "Save" : ' & _GUICtrlToolbar_IndexToCommand($hToolbar, $iIndex))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main