Функция _GUICtrlTab

_GUICtrlTab_GetItemState

Возвращает состояние вкладки

#include <GuiTab.au3>
_GUICtrlTab_GetItemState($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор или идентификатор элемента
$iIndex	Индекс вкладки, отсчёт от 0

Возвращаемое значение

Успех: Возвращает состояние вкладки, целое число, комбинация следующих значений:
$TCIS_BUTTONPRESSED - Вкладка выбрана/нажата
$TCIS_HIGHLIGHTED - Вкладка подсвечена

См. также

_GUICtrlTab_SetItemState

Пример

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>

$Debug_TAB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $hTab

; Создаёт GUI
GUICreate("Получает состояние вкладки", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296, $TCS_BUTTONS)
GUISetState()

; Вставляет вкладки
_GUICtrlTab_InsertItem($hTab, 0, "Вкладка 1")
_GUICtrlTab_InsertItem($hTab, 1, "Вкладка 2")
_GUICtrlTab_InsertItem($hTab, 2, "Вкладка 3")

; Установить / получить состояние вкладки 2
_GUICtrlTab_SetItemState($hTab, 1, $TCIS_BUTTONPRESSED)
MsgBox(4160, "Информация", "Состояние вкладки 2: " & _ExplainItemState(_GUICtrlTab_GetItemState($hTab, 1)))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main

Func _ExplainItemState($iState)
Local $sText = ""
If $iState = 0 Then $sText &= "Нет установленных флагов состояния на этой вкладке" & @LF
If BitAND($iState, $TCIS_BUTTONPRESSED) Then $sText &= "Кнопка нажата" & @LF
If BitAND($iState, $TCIS_HIGHLIGHTED) Then $sText &= "Кнопка подсвечена"
Return $sText
EndFunc ;==>_ExplainItemState