↑  ←  Описание функции

_GUICtrlSlider_GetRange

Возвращает минимальное и максимальное значения позиций ползунка

#include <GuiSlider.au3>
_GUICtrlSlider_GetRange($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:

    [0] - Минимальная значение позиции в элементе
    [1] - Максимальное значение позиции в элементе

См. также

_GUICtrlSlider_SetRange, _GUICtrlSlider_GetRangeMax, _GUICtrlSlider_GetRangeMin

Пример

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

$Debug_S = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aRange, $hSlider

    ; Создаёт GUI
    GUICreate("Получает диапазон", 400, 296)
    $hSlider = GUICtrlCreateSlider(2, 2, 396, 35, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    GUISetState()

    ; Получает диапазон
    $aRange = _GUICtrlSlider_GetRange($hSlider)
    MsgBox(4160, "Информация", StringFormat("Диапазон: %d - %d", $aRange[0], $aRange[1]))

    ; Устанавливает диапазон
    _GUICtrlSlider_SetRange($hSlider, 20, 50)

    ; Получает диапазон
    $aRange = _GUICtrlSlider_GetRange($hSlider)
    MsgBox(4160, "Информация", StringFormat("Диапазон: %d - %d", $aRange[0], $aRange[1]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main