↑  ←  Описание функции

_GUICtrlRichEdit_SetModified

Устанавливает или сбрасывает флаг модификации

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetModified($hWnd, $fState = True)

Параметры

$hWnd Дескриптор элемента
$fState Устанавливает новое значение флага модификации:
    True - Указывает, что текст был изменен (по умолчанию)
    False - Указывает отсутствие изменений.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $fState не является True или False

Примечания

Система автоматически устанавливает флаг модификации False при создании элемента.
Если текст элемента изменился, либо пользователем, либо программно, то система устанавливает флаг True Используйте функцию _GUICtrlRichEdit_IsModified, чтобы получить текущее состояние флага.

См. также

_GUICtrlRichEdit_IsModified

См. также

Искать $EM_SETMODIFY в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, '', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    Report("Начальное состояние после создания элемента")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Добавленный текст")
                        Report("Добавлен некоторый текст")
                    Case 2
                        _GUICtrlRichEdit_SetModified($hRichEdit, False)
                        Report("После очистки флага модификации")
                    Case 3
                        GUICtrlSetData($lblMsg, 'Введите какой нибудь текст, затем кликайте "Далее"')
                        ControlFocus($hRichEdit, "", "")
                    Case 4
                        Report("После ввода текста")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg &=  @cr & "состояние флага = " & _GUICtrlRichEdit_IsModified($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report