↑  ←  Описание функции

_GUICtrlRichEdit_SetLimitOnText

Изменяет количество символов, которые могут быть введены, вставлены или переданы как Rich Text Format

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText($hWnd, $iNewLimit)

Параметры

$hWnd Дескриптор элемента
$iNewLimit Новое ограничение

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $iNewLimit не является положительным числом или 0

Примечания

Эта функция устанавливает ограничение на количество символов, которое пользователь может ввести или вставить в элемент Rich Edit.

Это также ограничивает количество символов текста RTF, которое может передаваться при использовании _GUICtrlRichEdit_StreamFromFile и _GUICtrlRichEdit_StreamFromVar.

Это не ограничивает количество символов простого текста, которое может быть передано.

Начальное ограничение: 32,767 символов.

См. также

_GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar, _GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamFromVar

См. также

Искать EM_EXLIMITTEXT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $btnNext, $lblMsg, $hRichEdit, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
                        GUICtrlSetData($lblMsg, "1. Установлен лимит 65,536 символов")
                    Case 2
                        _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
                        GUICtrlSetData($lblMsg, "2. Установлен лимит 100,000 символов")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main