↑  ←  Описание функции

_GUICtrlRichEdit_SetFont

Устанавливает атрибуты шрифта выделенного текста или, если нет выделенного текста, то для текста в позиции курсора

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetFont($hWnd [, $iPoints = Default [, $sName = Default [, $iCharset = Default [, $iLcid = Default]]]])

Параметры

$hWnd Дескриптор элемента
$iPoints [необязательный] Размер шрифта
$sName [необязательный] Имя шрифта, например "Courier", но не "Courier Bold"
$iCharSet [необязательный] Кодировка - одна из:
    $ANSI_CHARSET - 0
    $BALTIC_CHARSET - 186
    $CHINESEBIG5_CHARSET - 136
    $DEFAULT_CHARSET - 1
    $EASTEUROPE_CHARSET - 238
    $GB2312_CHARSET - 134
    $GREEK_CHARSET - 161
    $HANGEUL_CHARSET - 129
    $MAC_CHARSET - 77
    $OEM_CHARSET - 255
    $RUSSIAN_CHARSET - 204
    $SHIFTJIS_CHARSET - 128
    $SYMBOL_CHARSET - 2
    $TURKISH_CHARSET - 162
    $VIETNAMESE_CHARSET - 163
$iLcid [необязательный] Смотрите http://www.microsoft.com/globaldev/reference/lcid-all.mspx

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $iPoints не является положительным числом
103 - $sName не является алфавитным
104 - $iCharset не является числом
105 - $iLcid не является числом

Примечания

Если параметр не указан (или указано ключевое слово Default), то его значение не изменяется

См. также

_GUICtrlRichEdit_GetFont, _GUICtrlRichEdit_ChangeFontSize

См. также

Искать EM_SETCHARFORMAT в библиотеке MSDN, Искать LOGFONT в библиотеке MSDN,

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
OnAutoItExitRegister('_OnExit') ; Освобождает ресурсы RichEdit даже при завершении скрипта с ошибкой

$hGui = GUICreate("Устанавливает шрифт", 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Это текст", 10, 10, 400, 220, _
        BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$iButton = GUICtrlCreateButton("Установить шрифт", 200, 310, 110, 30)
GUISetState()

; Выделяет текст
_GUICtrlRichEdit_SetSel($hRichEdit, 0, -1, True)

While 1
    Switch GUIGetMsg()
        Case $iButton
            ; Устанавливает размер и имя шрифта выделенного текста
            $iFontSize = Random(10, 34, 1)
            _GUICtrlRichEdit_SetFont($hRichEdit, $iFontSize, "Times New Roman")
            ; _GUICtrlRichEdit_SetFont($hRichEdit, 15, "Arial")
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _OnExit()
    ; Для версий ниже 3.3.8.0 обязательно удаление RichEdit или GUI для освобождения ресурсов RichEdit
    _GUICtrlRichEdit_Destroy($hRichEdit)
    GUIDelete()
EndFunc